3

我需要从 DCG 形式的上下文无关文法中获取非确定性下推自动机的 delta 函数，并且执行此操作的算法非常简单：

A --> B对于语法中的每条规则，[q1, lambda, A] --> [B]向 delta 函数添​​加一个转换。

E --> c对于语法中的每条规则，[q1, c, c] --> [lambda]向 delta 函数添​​加一个转换。

将转换[q0, lambda, z0] --> [q1, S*z0]和添加[q1, lambda, z0] --> [q2, z0]到 delta 函数。

每个大写字母都是非终结符，每个小写字母都是终结符。lambda是空字符串，S是文法的初始符号，*是连接运算符，z0是栈顶符号。

这意味着语法

S --> A*b | B | y
A --> w*x | x
B --> A*b

使用 delta 函数生成下推自动机

[q0, lambda, z0] --> [q1, S*z0]
[q1, lambda, S] --> [q1, A*b]
[q1, lambda, S] --> [q1, B]
[q1, lambda, S] --> [q1, y]
[q1, lambda, A] --> [q1, w*x]
[q1, lambda, A] --> [q1, x]
[q1, lambda, B] --> [q1, A*b]
[q1, b, b] --> [q1, lambda]
[q1, w, w] --> [q1, lambda]
[q1, x, x] --> [q1, lambda]
[q1, y, y] --> [q1, lambda]
[q1, lambda, z0] --> [q2, z0]

我必须在 Prolog 中实现这个算法（从用户那里获取语法并返回 delta 函数），我很困惑，因为这是我第一次使用逻辑编程语言。

我想我可以将语法翻译成它的谓词形式，然后“迭代”所有谓词，并以某种方式将已经“遍历”的谓词添加到一个列表中，这样我就可以处理这个列表并返回 delta 函数。但我认为这是一种非常复杂的命令式做事方式，为此使用 Prolog 毫无意义。

也许这个问题有一个更优雅的解决方案，所以我想知道这样的解决方案是否存在。

4

1 回答 1

2

这里有一个可能的编码

g2nfa(Grammar, Delta) :-
    maplist(transitions, Grammar, DeltaT),
    append(DeltaT, DeltaF),
    Initial = (q0, lambda, z0 --> q1, 'S'*z0),
    Final = (q1, lambda, z0 --> q2, z0),
    append([[Initial], DeltaF, [Final]], Delta).

transitions(Sym --> Alternatives, Transitions) :-
    phrase(transition(Sym, Alternatives), Transitions).

transition(Sym, A|As) --> state(Sym, A), !, transition(Sym, As).
transition(Sym, A) --> state(Sym, A).
state(Sym, A) --> [(q1, lambda, Sym --> q1, A)].

test :-
    g2nfa([( 'S' --> 'A'*b | 'B' | y ),
           ( 'A' --> w*x | x ),
           ( 'B' --> 'A'*b )
          ], T), maplist(writeln, T).

这似乎满足您的要求

?- test.
q0,lambda,z0-->q1,S*z0
q1,lambda,S-->q1,A*b
q1,lambda,S-->q1,B
q1,lambda,S-->q1,y
q1,lambda,A-->q1,w*x
q1,lambda,A-->q1,x
q1,lambda,B-->q1,A*b
q1,lambda,z0-->q2,z0
true.

所以你可以计算出语法细节。请注意，第二个重写规则（对于语法中的每个规则 E --> c，将转换 [q1, c, c] --> [lambda] 添加到 delta 函数。）尚未在您的示例中应用。

于 2012-06-16T14:04:04.343 回答