2

我刚刚和 Chicago Boss 一起学习 Erlang，想知道我怎么能做类似的事情（在伪代码中）：

foreach (items as item)
    if (i % 10 == 0)
        <tr>
    endif
    <td>...</td>
    if (i++ % 10 == 0)
        </tr>
    endif
endforeach

在我的模板中？

4

2 回答 2

1

Erlang 是函数式语言，所以惯用的方式是以函数式的方式来做。我们准备了功能，它将首先将您的数据制成表格：

-module(tabify).

-export([tabify/2]).

tabify(N, L) when is_list(L), is_integer(N), N > 0 ->
  tabify_(N, L).

tabify_(_, []) -> [];
tabify_(N, L) ->
  {Row, Rest} = row(L, N),
  [Row|tabify_(N, Rest)].

row(L, N) ->
  row(L, N, []).

row([], _, Accu) -> {lists:reverse(Accu), []};
row(Rest, 0, Accu) -> {lists:reverse(Accu), Rest};
row([H|T], N, Accu) -> row(T, N-1, [H|Accu]).

现在我们可以通过以下方式使用它：

1> c(tabify).
{ok,tabify}
2> Data = [integer_to_list(X) || X <- lists:seq(1,100)].
["1","2","3","4","5","6","7","8","9","10","11","12","13",
 "14","15","16","17","18","19","20","21","22","23","24","25",
 "26","27","28",
 [...]|...]
3> Table = tabify:tabify(10,Data).
[["1","2","3","4","5","6","7","8","9","10"],
 ["11","12","13","14","15","16","17","18","19","20"],
 ["21","22","23","24","25","26","27","28","29","30"],
 ["31","32","33","34","35","36","37","38","39","40"],
 ["41","42","43","44","45","46","47","48","49","50"],
 ["51","52","53","54","55","56","57","58","59","60"],
 ["61","62","63","64","65","66","67","68","69","70"],
 ["71","72","73","74","75","76","77","78","79","80"],
 ["81","82","83","84","85","86","87","88","89","90"],
 ["91","92","93","94","95","96","97","98","99","100"]]
4> T = [["<tr>", [["<td>", Item, "</td>"] || Item <- Row ], "</tr>"]|| Row <- Table].
[["<tr>",
  [["<td>","1","</td>"],
   ["<td>","2","</td>"],
   ...

而不是让 io 子系统完成其余的工作。上面的结构是众所周知的 iolist ，如果你把它放在任何 io 中，它将以与以下相同的方式正确序列化：

6> iolist_to_binary(T).
<<"<tr><td>1</td><td>2</td><td>3</td><td>4</td><td>5</td><td>6</td><td>7</td><td>8</td><td>9</td><td>10</td></tr><tr><t"...>>

如果表中有数千个项目并且效率至关重要，那么您可以将所有列表常量转换为二进制。也可以在Data. 作为最后的手段，您可以tabify/2以更有效但可读性更低的方式重写和格式化。

于 2012-06-16T13:45:50.460 回答
0

如果你需要“tabify”一个列表，你可以使用我刚刚创建的这个函数：

tab_list(List1) ->
    lists:append(
        lists:flatten(
            lists:map(
                fun({Item, Idx}) -> 
                    if 
                        ((Idx - 1) rem 10) == 0 -> lists:concat(["<TR><TD>", Item, "</TD>"]); 
                        (Idx rem 10) == 0 -> lists:concat(["<TD>", Item, "</TD></TR>"]);
                        true -> lists:concat(["<TD>", Item, "</TD>"])
                    end
                end,
            lists:zip(List1, lists:seq(1, length(List1)))
            )
        ),
    if (length(List1) rem 10) == 0 -> ""; true -> "</TR>" end
).

当传递一个类似的列表["a", "b", "c", "d", "e", "f", "g", "h", "i", "l", "m", "n", "o", "p", "q", "r", "s", "t", "u", "v", "z"]时，会产生以下结果：

"<TR><TD>a</TD><TD>b</TD><TD>c</TD><TD>d</TD><TD>e</TD><TD>f</TD><TD>g</TD><TD>h</TD><TD>i</TD><TD>l</TD></TR><TR><TD>m</TD><TD>n</TD><TD>o</TD><TD>p</TD><TD>q</TD><TD>r</TD><TD>s</TD><TD>t</TD><TD>u</TD><TD>v</TD></TR><TR><TD>z</TD></TR>"

这是你需要的吗？只要问你有什么问题！

于 2012-06-15T15:12:08.773 回答