1

我在“重温过去”部分的 datomic 教程遇到问题http://datomic.com/company/resources/tutorial.html

对于以下两个查询：

query = "[:find ?c :where [?c :community/name]]";
db_asOf_schema = conn.db().asOf(schema_tx_date);
System.out.println(Peer.q(query, db_asOf_schema).size()); // 0

db_since_data = conn.db().since(data_tx_date);
System.out.println(Peer.q(query, db_since_data).size()); // 0

我已经在 clojure 中尝试过这些命令，但无法让它们按照教程中的描述工作：

(since (db conn) (java.util.Date.) ) 
;; It should return 0 but returns the whole database instead

(def ts (q '[:find ?when :where [?tx :db/txInstant ?when]] (db conn)))

(count (since (db conn) (ffirst (reverse (sort ts))))))
;; returns 13, but should return 0

(count (as-of (db conn) (ffirst (sort ts)))))
;; returns 13, but should return 0

我不太确定这是正确的行为，我做错了什么吗？

4

1 回答 1

9

如果您正在阅读 Clojure 中的西雅图教程，那么可能最重要的一件事就是知道工作的 Clojure 代码包含在 Datomic 发行版中。文件名是samples/seattle/getting-started.clj，您可以在 REPL 中简单地跟随。

在您的问题中对 Clojure 代码的两个观察：

该since函数被记录为返回一个数据库值，而不是一个数字，因此您看到的行为与预期的一样。为了查看数据库中的内容，您需要发出查询。

数据库没有任何 Clojurecount函数的书面语义，因此您不应调用count它们。同样，如果您想查看数据库中的内容，则需要发出查询，例如

;; Find all transaction times, sort them in reverse order
(def tx-instants (reverse (sort (q '[:find ?when :where [_ :db/txInstant ?when]]
                                       (db conn)))))

;; pull out two most recent transactions, most recent loaded
;; seed data, second most recent loaded schema
(def data-tx-date (ffirst tx-instants))
(def schema-tx-date (first (second tx-instants)))

;; make query to find all communities
(def communities-query '[:find ?c :where [?c :community/name]])

;; find all communities as of schema transaction
(let [db-asof-schema (-> conn db (d/as-of schema-tx-date))]
  (println (count (seq (q communities-query db-asof-schema)))))

;; find all communities as of seed data transaction
(let [db-asof-data (-> conn db (d/as-of data-tx-date))]
  (println (count (seq (q communities-query db-asof-data)))))

;; find all communities since seed data transaction
(let [db-since-data (-> conn db (d/since data-tx-date))]
  (println (count (seq (q communities-query db-since-data)))))

希望这可以帮助。如果您有更多问题，还有一个Datomic google 小组。

于 2012-06-14T18:05:33.833 回答