0

这一直困扰着我一段时间。我正在使用 oracle 流将消息写入 oracle AQ 队列作为存储过程的一部分。下面是显示相关部分的存储过程：

CREATE OR REPLACE PROCEDURE ESBEVENT.esb_dml_handler(in_any IN ANYDATA) IS

l_enqueue_options dbms_aq.enqueue_options_t;
l_message_properties dbms_aq.message_properties_t;
l_message sys.aq$_jms_text_message;
l_msgid raw(16);
l_xmlmsg SYS.XMLTYPE;
err_num NUMBER;
err_msg VARCHAR2(100);

BEGIN
    BEGIN
    l_message := sys.aq$_jms_text_message.construct;
    l_xmlmsg := DBMS_STREAMS.CONVERT_LCR_TO_XML(in_any);
    l_message.set_text(l_xmlmsg.getClobVal());

    dbms_aq.enqueue
    ( queue_name => 'esbevent.esb_jms_queue'
    , enqueue_options => l_enqueue_options
    , message_properties => l_message_properties
    , payload => l_message
    , msgid => l_msgid
    );
    COMMIT;

    err_num := '';
    err_msg := 'Message Queued Successfully';

    EXCEPTION
    WHEN OTHERS THEN
        err_num := SQLCODE;
        err_msg := SUBSTR(SQLERRM, 1, 1000);
        INSERT INTO esbevent.esb_dml_handler_error_t VALUES (SYSDATE, err_num||' - '||err_msg );
END;

INSERT INTO esbevent.esb_jms_msg_memento_t VALUES (esb_jms_msg_memento_seq.nextval,     SYSDATE, l_xmlmsg, err_num||' - '||err_msg );
COMMIT;


END;

在入队之后，我将作为 XMLTYPE 发送的消息存储在表 esb_jms_msg_memento_t 中。如果我们在后续处理中遇到问题，这是为了启用重新发送。我现在正在尝试编写一个块来提取 XMLTYPE 字段数据并将其再次写入 AQ。目前情况如下：

DECLARE
   l_enqueue_options      DBMS_AQ.ENQUEUE_OPTIONS_T;
   l_message_properties   DBMS_AQ.MESSAGE_PROPERTIES_T;
   l_message              SYS.aq$_jms_text_message;
   l_msgid                RAW (16);
   l_xmlmsg               XMLTYPE;

BEGIN
   SELECT msg_payload
     INTO l_xmlmsg
     FROM esb_jms_msg_memento_t
    WHERE UNIQUE_ID = '815929';

   l_message.set_text (l_xmlmsg.getClobVal ()); --null self error here


   DBMS_AQ.enqueue (queue_name           => 'esbevent.esb_jms_queue',
                    enqueue_options      => l_enqueue_options,
                    message_properties   => l_message_properties,
                    payload              => l_message,
                    msgid                => l_msgid);
   COMMIT;
END;

当我运行它时，我得到了错误：

ORA-30625：不允许对 NULL SELF 参数进行方法调度 ORA-06512：在第 22 行

看来我可以将 XMLTYPE 变量插入 XMLTYPE 字段，但反过来不行？？？

4

1 回答 1

0

我一发帖就解决了。。。

忘记构建 l_message：

l_message := sys.aq$_jms_text_message.construct;

哦！

于 2012-06-14T00:43:46.397 回答