3

我正在尝试使用 HTTPBuilder 类将 XML 数据发布到 URL。目前我有：

def http = new HTTPBuilder('http://m4m:aghae7eihuph@m4m.fetchapp.com/api/orders/create')
http.request(POST, XML) {
body = {
        element1 {
            subelement 'value'
            subsubelement {
                key 'value2'
            }
        }
    }           

    response.success = { /* handle success*/ }
    response.failure = { resp, xml -> /* handle failure */ }
}

经过检查，我发现请求确实以 XML 作为正文。不过，我有 3 个问题。第一个是，它省略了经典的 xml 行：

<?xml version="1.0" encoding="UTF-8"?>

它必须位于正文的顶部，其次内容类型也未设置为：

application/xml

最后，对于 XML 中的一些元素，我需要设置属性，例如：

<element1 type="something">...</element1>

但我不知道如何以上述格式执行此操作。有谁知道怎么做？或者也许是另一种方式？

4

1 回答 1

5
  1. mkp.xmlDeclaration()在标记开头添加 XML 声明行。
  2. ContentType.XML作为第二个参数传递给 request 将Content-Type标头设置为application/xml. 我不明白为什么这对你不起作用，但你可以尝试使用一个字符串application/xml代替。
  3. 要在元素上设置属性，请在标记构建器中使用以下语法：element1(type: 'something') { ... }

这是一个例子：

@Grab(group='org.codehaus.groovy.modules.http-builder', module='http-builder', version='0.5.2')
import groovyx.net.http.*

new HTTPBuilder('http://localhost:8080/').request(Method.POST, ContentType.XML) {
    body = { 
        mkp.xmlDeclaration()
        element(attr: 'value') {
            foo { 
                bar()
            } 
        }
    }
}

生成的 HTTP 请求如下所示：

POST / HTTP/1.1
Accept: application/xml, text/xml, application/xhtml+xml, application/atom+xml
Content-Length: 71
Content-Type: application/xml
Host: localhost:8080
Connection: Keep-Alive
Accept-Encoding: gzip,deflate

<?xml version='1.0'?>
<element attr='value'><foo><bar/></foo></element>
于 2012-06-13T15:30:31.847 回答