5

你能帮我从这个文件 http://techpatterns.com/downloads/firefox/useragentswitcher.xml列出浏览器 到 txt 文件，用 %tab% 分隔符分隔吗？

应该有 3 或 4 列：

1）来自示例数据的文件夹描述： <folder description="Browsers - Windows">

2）来自示例数据的浏览器类型：<folder description="Legacy Browsers">

3）来自示例数据的用户代理：<useragent description="Avant Browser 1.2" useragent="Avant Browser/1.2.789rel1 (http://www.avantbrowser.com)" app

在这里我看到了第一个问题，因为有些浏览器不在文件夹中<folder description="Legacy Browsers">"，而是在<separator/>

所以第一列应该定义系统，第二列是类型，第三列是浏览器。

下一个问题是 Devises 文件夹包含一个文件夹。

@echo off 
Setlocal EnableDelayedExpansion
SET file=useragentswitcher.xml
SET delim="

FOR /F "tokens=* skip=1" %%F IN (!file!) DO (
  REM echo %%F
  call :parse "%%F" > temp.txt
  FOR /F "tokens=1,2,3,4,5,6,7 skip=1 delims=" %%A IN (temp.txt) DO (
    IF "%%A"=="folder" (
      SET /A level=!level!+1
      echo Level:!level!
      ) ELSE IF "%%A"=="/folder" (
          SET /A level=!level!-1
          echo Level:!level!
        )

   echo A:%%A
  )
  pause
)

exit /b

:parse
Setlocal EnableDelayedExpansion
  SET A=%*
  REM REMOVE double paranthesis and <> 
  SET A=!A:~2,-2!
  REM replace double qoutes
  SET A=!A:"=µ!
  FOR /F "tokens=1,2 delims=µ=" %%A IN ("!A!") DO (
    SET first=%%A
    SET second=%%B
    echo !first!
    FOR /F "tokens=1,2 delims= " %%A IN ("!first!") DO (
      echo %%A
      echo %%B
    )
    echo !second!
  )
endlocal
exit /b

这会解析该行的一个标签，我现在将使用它。

4

3 回答 3

6

看来您应该能够找到比批处理更好的工具来解析 XML...

但我相信下面的代码就是你要找的。

因为文件夹的数量不同，我交换了输出中列的顺序。我将浏览器描述放在首位，然后是文件夹，每列一个。这允许固定每列的定义。

我使用了 jeb 的答案中的信息"作为 FOR 分隔符。

编辑 - 我简化了代码

注意 - 第一次尝试是为了处理使用 Internet Explorer 检索到的 XML 副本而编写的。从那以后，我发现 IE 改变了文件的格式。此代码高度依赖于文件的确切格式，因此它不适用于原始 XML。它还作为一个例子说明为什么批处理是解析 XML 的糟糕选择

@echo off
setlocal enableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set "folder0="
>%output% (
  for /f usebackq^ tokens^=1^,2^ delims^=^=^" %%A in (%input%) do (
    for %%N in (!cnt!) do (
      if "%%A"=="- <folder description" (
        set /a cnt+=1
        for %%M in (!cnt!) do set "folder%%M=!folder%%N!%TAB%%%B"
      )
      if "%%A"=="  </folder>" (
        set /a cnt-=1
      )
      if "%%A"=="  <useragent description" (
        echo %%B!folder%%N!
      )
    )
  )
)

如果出现在任何描述中，代码将失败!，因为延迟扩展会破坏包含!. 我检查了，您的文件不包含!任何描述。

可以修改代码以!在描述中处理，但它会变得更加复杂。它需要打开和关闭延迟扩展，并在 ENDLOCAL 屏障上保存变量值。

上面的代码高度依赖于 XML 的格式。如果非标准破折号被删除，或者空白排列发生变化，它将失败。

下面的变体更健壮一些，但它仍然要求每一行都只包含一个 XML 标记。

@echo off
setlocal enableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set "folder0="
>%output% (
  for /f usebackq^ tokens^=1^,2^ delims^=^=^" %%A in (%input%) do (
    for %%N in (!cnt!) do (
      set "test=%%A"
      if "!test:<folder description=!" neq "!test!" (
        set /a cnt+=1
        for %%M in (!cnt!) do set "folder%%M=!folder%%N!%TAB%%%B"
      )
      if "!test:</folder>=!" neq "!test!" (
        set /a cnt-=1
      )
      if "!test:<useragent description=!" neq "!test!" (
        echo %%B!folder%%N!
      )
    )
  )
)

编辑 - 最后一个版本

这是一个可以!在数据中处理的版本。我在输出中添加了一个附加列。第一列仍然是浏览器描述。第二列是用户代理字符串。其余列是文件夹。该解决方案使用延迟扩展切换技术。它还使用额外的 FOR /F 来跨 ENDLOCAL 屏障保留变量值。

@echo off
setlocal disableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set folder0=""
>%output% (
  for /f usebackq^ tokens^=1-4^ delims^=^=^" %%A in (%input%) do (
    set "test=%%A"
    set "desc=%%B"
    set "agent=%%D"
    setlocal enableDelayedExpansion
    for %%N in (!cnt!) do (
      if "!test:<folder description=!" neq "!test!" (
        set /a cnt+=1
        for %%M in (!cnt!) do for /f "delims=" %%E in ("!folder%%N!") do (
          endlocal
          set "folder%%M=%%~E%TAB%%%B"
          set "cnt=%%M"
        )
      ) else if "!test:</folder>=!" neq "!test!" (
        endlocal
        set /a cnt-=1
      ) else if "!test:<useragent description=!" neq "!test!" (
        echo !desc!%TAB%!agent!!folder%%N!
        endlocal
      ) else endlocal
    )
  )
)
于 2012-06-13T16:06:50.817 回答
2

检查xpath.bat - 可以通过给定的 xpath 表达式从 xml 获取值的脚本：

call xpath.bat "useragentswitcher.xml" "//folder/@description"
于 2017-02-07T13:55:42.967 回答
1

回答您的评论How should I use double quotes as delimiter?

只需使用表格

FOR /F tokens^=1^,2^ delims^=^" %%B IN ("%%A") DO

这是如何工作的？
通常，您不能将引号字符用作分隔符。
这是唯一已知的解决方法，重要的是缺少 FOR/F 选项周围的正常引号。
但必须将选项仅解析为一个标记，因此您需要转义所有标准批处理解析器分隔符（空格制表符 =,;）。
引号不是批处理分隔符，但也需要对其进行转义，以避免行的其余部分被引用，然后解析器将失败。
但是您可以更改^"with ""，因为第二个引号将被忽略。

FOR /F tokens^=1^,2^ delims^="" %%B IN ("%%A") DO ...
于 2012-06-13T13:47:53.410 回答