delphi - 从触发器下载delphi文件并捕获文件名

Question

我有一个网站的网址。它看起来像这样：http ://www.example.com/downloads/file/4789/download ？

我想将文件保存到我的系统中，但我不知道如何获取示例中由 URL 触发的下载的文件名。有些文件是 pdf 其他文件是 doc 和 rtf 等。

如果有人能指出文件名问题的方向以及使用哪些组件，我将不胜感激。

Answer 1

要从 url 获取文件名，您可以检索 HEAD 信息并检查Content Disposition标头字段。对于此任务，您可以使用 TIdHTTP indy 组件。如果 Content Disposition 没有文件名，您可以尝试解析 url。

试试这个样本。

{$APPTYPE CONSOLE}

{$R *.res}

uses
  IdURI,
  IdHttp,
  SysUtils;

function GetRemoteFileName (const URI: string) : string;
var
  LHttp: TIdHTTP;
begin
  LHttp := TIdHTTP.Create(nil);
  try
    LHttp.Head(URI);
    Result:= LHTTP.Response.RawHeaders.Params['Content-Disposition', 'filename'];
    if Result = '' then
     with TIdURI.Create(URI) do
      try
       Result := Document;
      finally
       Free;
      end;
  finally
    LHttp.Free;
  end;
end;

begin
  try
    Writeln(GetRemoteFileName('http://dl.dropbox.com/u/12733424/Blog/Delphi%20Wmi%20Code%20Creator/Setup_WmiDelphiCodeCreator.exe'));
    Writeln(GetRemoteFileName('http://studiostyl.es/settings/downloadScheme/1305'));

  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.