0

我有一些代码加载到 xml 文件中，并使用“XslCompiledTransform”对其应用 XSLT。我现在需要更改代码，因为输入文件可能不是 XML，也可能是 CSV 文件。我有一个 XSLT，可以将 CSV 转换为我想要的格式，但它使用硬编码路径。我遇到的问题是输入文件名会改变，所以我可以在名称中使用宽卡吗？其次，在代码中，我可以将文件作为字符串传递给 XSLT 对象并让结果落在底部吗？我一直在做一些谷歌搜索，但没有找到任何代码来做到这一点。甚至可能吗？

这是我正在使用的 XSLT。不是硬编码的路径和文件名。

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:fn="fn"
    exclude-result-prefixes="xs fn">

<xsl:output indent="yes" encoding="US-ASCII"/>

<xsl:param name="pathToCSV" select="'file:///C:/Downloads/inputcsv.csv'"/>

<xsl:function name="fn:getTokens" as="xs:string+">
    <xsl:param name="str" as="xs:string"/>
        <xsl:analyze-string select="concat($str, ',')" regex='(("[^"]*")+|[^,]*),'>
            <xsl:matching-substring>
                <xsl:sequence select='replace(regex-group(1), "^""|""$|("")""", "$1")'/>
            </xsl:matching-substring>
        </xsl:analyze-string>
</xsl:function>

<xsl:template match="/" name="main">
    <xsl:choose>
        <xsl:when test="unparsed-text-available($pathToCSV)">
            <xsl:variable name="csv" select="unparsed-text($pathToCSV)"/>
            <xsl:variable name="lines" select="tokenize($csv, '&#xD;')" as="xs:string+"/>
            <xsl:variable name="elemNames" select="fn:getTokens($lines[1])" as="xs:string+"/>
            <root>
                <xsl:for-each select="$lines[position() > 0]">
                    <row>
                        <xsl:variable name="lineItems" select="fn:getTokens(.)" as="xs:string+"/>

                        <xsl:for-each select="$elemNames">
                            <xsl:variable name="pos" select="position()"/>
                            <column>
                                <xsl:value-of select="$lineItems[$pos]"/>
                            </column>
                        </xsl:for-each>
                    </row>
                </xsl:for-each>
            </root>
        </xsl:when>
        <xsl:otherwise>
            <xsl:text>Cannot locate : </xsl:text><xsl:value-of select="$pathToCSV"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>
4

1 回答 1

2

那么 XslCompiledTransform 是一个 XSLT 1.0 处理器，因此使用 XslCompiledTransform 无法使用 XSLT 2.0 功能unparsed-text，您需要使用 Saxon 9 或 XmlPrime 或 AltovaXML 用于 XSLT 2.0。

然后您可以将一个参数传递给您发布的样式表，因为它具有全局xsl:param命名pathToCSV，您如何传递该参数取决于您要使用的 XSLT 处理器的 API（或者如果您只想执行它的命令行参数，来自命令行的样式表）。

于 2012-06-11T10:47:58.700 回答