2

目前只是与 Praat 合作，我正在尝试编写一个脚本来使用 3 个声音（叙述）文件的集合来执行以下操作。我已经做到了 c)，脚本部分相对容易。我没有得到的是如何将其写入具有这些列的文本文件。任何帮助都会很棒！

a) 创建一个程序，提取叙事 1-3 的每一个的音素层上的所有间隔，这些间隔代表标签为单个字母的元音，并保持时间。我需要每个生成的声音都有一个适当的标签来标识相关的元音

b) 创建对应于这些间隔中的每一个的共振峰 (burg) 对象

c) 计算每个共振峰对象的中点

c) 在每个中点获取共振峰 1、2 和 3 的值

d) 写入具有以下标题的文本文件：

叙述# 标签中点时间 F1 F2 F3

在此之下，每个元音的适当信息

4

2 回答 2

4

简单的方法

最简单的方法是将输出写入Table对象，然后使用 Praat 的Save to comma-separated file命令将其保存到外部文件。下面的示例使用新的（稍微更合理的）新语法，因此请确保在尝试之前更新 Praat（或尝试此答案的编辑历史记录中的速记版本）。

这是一个例子：

# Create a Table with no rows
table = Create Table with column names:
..."table", 0, "Narrative Label Midpoint Time F1 F2 F3"

for i to number_of_intervals
  # Assuming you have your Formant objects in an array named "burg"
  selectObject(burg[i])
  # Run your analysis here
  # For this example, I'm assuming values for the columns are in
  # variables called narrative$, label$, midpoint, time, f1, f2 and f3

  selectObject(table)
  Append row
  current_row = Get number of rows
  # Insert your values
  Set string value:  current_row, "Narrative", narrative$
  Set string value:  current_row, "Label", label$
  Set numeric value: current_row, "Midpoint", midpoint 
  Set numeric value: current_row, "Time", time
  Set numeric value: current_row, "F1", f1 
  Set numeric value: current_row, "F2", f2
  Set numeric value: current_row, "F3", f3
endfor

# Save it!
# Remember to select it if the table is not the active selection at
# the end of the loop
Save to comma-separated file: /path/to/file
# And then you can get rid of it
removeObject(table)

或者你可以使用，如果你喜欢标签

Save to tab-separated file: /path/to/file

请注意，此方法不允许您使用“Narrative#”作为列名。

'l33t' 方式

或者，您可以使用 Praat 的文件指令按照文档中的说明直接写入文件：

sep$ = ","
# sep$ = tab$

# Create / overwrite file and write header
writeFileLine: "/path/to/file",
  ..."Narrative#" + sep$ +
  ..."Label"      + sep$ + 
  ..."Midpoint"   + sep$ +
  ..."Time"       + sep$ +
  ..."F1"         + sep$ +
  ..."F2"         + sep$ +
  ..."F3"

for i to number_of_intervals
  selectObject(burg[i])
  # Run your analysis here

  appendFileLine: "/path/to/file",
    ...narrative$        + sep$ +
    ...label$            + sep$ +
    ...string$(midpoint) + sep$ +
    ...string$(time)     + sep$ + 
    ...string$(f1)       + sep$ +
    ...string$(f2)       + sep$ +
    ...string$(f3)

endfor
于 2013-02-19T11:07:56.513 回答
0

Praat 用户组在这里有一个类似问题的答案。

于 2012-07-27T15:37:09.257 回答