delphi - 如何使用 Delphi 和 Indy 跟踪 URL 重定向？

Question

我收到了几封带有 url 链接的营销电子邮件，这些电子邮件从一个站点重定向到另一个站点。我想编写一个程序来使用 Delphi 和 Indy 跟踪每个 URL 重定向。我想遍历每个 URL，记录完整的 QueryString 以及在此过程中可能已设置的任何 Cookie。

我如何使用 D2010 附带的 Indy 组件来做到这一点？

Answer 1

首先，您需要一个 HTTP 客户端，它TIdHTTP位于 Indy 中。

现在你需要一个数据结构来保存你的结果：

  TRedirection = record
    queryString: String;
    cookies: TStrings;
  end;

  TRedirectionArray = array of TRedirection;

创建一个完成工作的类（需要一个类，因为事件函数定义为procedure of object）：

  TRedirectionTester = class
    private
      FRedirData: TRedirectionArray;
      procedure redirectEvent(Sender: TObject; var dest: string;
        var NumRedirect: Integer; var Handled: boolean; var VMethod: TIdHTTPMethod);
      procedure newCookie(ASender: TObject; ACookie: TIdCookie; var VAccept: Boolean);
    public
      function traverseURL(url: String): TRedirectionArray;
      property RedirData: TRedirectionArray read FRedirData;
  end;

这提供了基本功能 - 您可以traverseURL使用 URL 调用，它会返回一个TRedirectionArray包含查询字符串和 cookie 的内容。

然后实现OnRedirect事件：

procedure TRedirectionTester.redirectEvent(Sender: TObject; var dest: string;
  var NumRedirect: Integer; var Handled: boolean; var VMethod: TIdHTTPMethod);
var
  redirDataLength: Integer;
begin
  Handled := True;

  redirDataLength := Length(FRedirData);
  SetLength(FRedirData, redirDataLength + 1);

  FRedirData[redirDataLength].queryString := dest;
  FRedirData[redirDataLength].cookies := TStringList.Create;
end;

这将在数​​组中添加一个条目，并存储重定向的查询字符串。由于此重定向本身不包含 cookie（在请求重定向页面时设置了 cookie），因此您还不能在此处添加任何 cookie。

这就是为什么你需要一个OnNewCookie处理程序：

procedure TRedirectionTester.newCookie(ASender: TObject; ACookie: TIdCookie; var VAccept: Boolean);
var
  redirDataLength: Integer;
begin
  VAccept := True;

  redirDataLength := High(FRedirData);
  if (Assigned(FRedirData[redirDataLength].cookies)) then
    FRedirData[redirDataLength].cookies.Add(ACookie.CookieText);
end;

这只是将 添加CookieText到数据集中。该字段包含 cookie 的“摘要”——它是请求页面时发送的实际字符串数据。

最后，通过实现traverseURL函数把它放在一起：

function TRedirectionTester.traverseURL(url: String): TRedirectionArray;
var
  traverser: TIdHTTP;
begin
  traverser := TIdHTTP.Create();
  traverser.HandleRedirects := True;
  traverser.OnRedirect := redirectEvent;
  traverser.CookieManager := TIdCookieManager.Create();
  traverser.CookieManager.OnNewCookie := newCookie;

  SetLength(FRedirData, 1);
  FRedirData[0].queryString := url;
  FRedirData[0].cookies := TStringList.Create;

  traverser.Get(url);

  Result := FRedirData;
end;

它做的不多：它创建所需的对象，并分配事件处理程序。然后它添加第一个 url 作为第一个重定向（即使它不是真正的重定向，我添加它是为了完整性）。然后调用Get发送请求。它将在最终页面被网络服务器定位并返回后返回。

我用http://bit.ly/Lb2Vho对其进行了测试。

但是，这仅处理由 HTTP 状态代码 301 或 302 引起的重定向。据我所知，它不处理通过<meta>标签或 javascript 完成的重定向。要添加该功能，您必须检查对 的调用结果Get，并对其进行解析以搜索此类重定向。