9

在回答这个问题时，我发现了一些我无法解释的奇怪行为

for /f "delims=" %a in ('(for /l %z in (1,1,10^) do @echo %z^)') do @echo %a0

您将看到数字 10..100，现在只需添加管道，例如添加到sort或more，无论：

for /f "delims=" %a in ('(for /l %z in (1,1,10^) do @echo %z^)^|sort') do @echo %a0

%a和之间会有空格0！看起来通过管道回显某些内容会添加尾随空格，可以很容易地看到：

>_tempfile echo no space here
>_tempfile echo and here's a space|more

乃至

>_tempfile <nul set /p =also a space|sort

（可能使用 echo 打印提示）

当没有输出重定向（无论是文件还是命令）时，这不会发生。这是一个错误还是我错过了什么？我如何摆脱空间？（除了用 剥离最后一个字符的肮脏技巧var:~0,-1）

4

2 回答 2

8

优秀而有趣的问题（+1）

该空间是由 CMD 解析器的管道机制引入的，而不是由 SORT 引入的。

当您使用 FOR /F 执行命令时，该命令将在其自己的 CMD shell 中执行。此外，管道的每一侧都在其自己的 CMD shell 中执行。请参阅为什么在管道代码块中延迟扩展失败？了解更多信息。

因此，您的命令实际上实例化了 3 个 CMD 外壳，一个用于 FOR /F 命令，而后者又为管道的每一侧创建 2 个。

您可以使用 %CMDCMDLINE% 动态变量查看命令是如何被解析并输入到 CMD shell 中的。因为我们是从命令行执行命令，所以我们需要对变量名中的至少一个字符进行两次转义，以便在到达最里面的 CMD shell 之前它不会被扩展。

这是带有结果的命令（前导>是我的命令提示符）：

>for /f "delims=" %a in ('(echo %^^^cmdcmdline%^&for /l %z in (1,1,10^) do @echo %z^)^|sort') do @echo %a0
1 0
10 0
2 0
3 0
4 0
5 0
6 0
7 0
8 0
9 0
C:\Windows\system32\cmd.exe  /S /D /c" ( echo %cmdcmdline% & FOR /L %z in (1 1 10) do @ echo %z )" 0

输出的最后一行是用于管道左侧的命令行。您可以看到解析器如何在许多地方添加空格。

您可以通过使用简单的批处理脚本来回显值而不是 ECHO 命令来规避该问题。

echoArgs.bat

@echo(%*

现在，当您运行此命令时，您将获得所需的结果

>for /f "delims=" %a in ('(for /l %z in (1,1,10^) do @echoArgs %z^)^|sort') do @echo %a0
10
100
20
30
40
50
60
70
80
90

另一种规避该问题的方法是使用 ECHO 命令创建一个变量并适当地转义该变量的扩展。

>set cmd=@(echo %z)

>for /f "delims=" %a in ('(for /l %z in (1,1,10^) do %^^^cmd%^)^|sort') do @echo %a0
10
100
20
30
40
50
60
70
80
90

编辑

这个>_tempfile echo and here's a space|more例子也很有趣。输出文件末尾有一个额外的空间。但是 Chad Nouis 是正确的，因为左侧的重定向，什么都没有被排序。任何命令都可以在右侧使用，结果是一样的。

问题的根源仍然是解析器，但是解析器重组命令的方式很有趣。

>>_tempfile echo %^cmdcmdline%|rem

>type _tempfile
C:\Windows\system32\cmd.exe  /S /D /c" echo %cmdcmdline% 1>_tempfile"

注意重定向是如何从命令的开头移动到结尾的，并且1显式添加了文件句柄。您当然可以看到额外空间的来源。

于 2012-06-08T14:36:44.387 回答
0

重定向运算符适用于它们最接近的命令，而不是整行。

在您的三个测试用例中，您将echoandset命令的标准输出重定向到一个文件。通过重定向标准输出，没有任何东西可以通过管道传输到moreor sort。

在您的嵌套 for 循环示例中，我认为有一些不需要的括号会引起头痛。试试这个：

for /f "delims=" %a in ('for /l %z in (1,1,10^) do @echo %z^|sort') do @echo %a0
于 2012-06-08T15:23:26.063 回答