1

我的输入 XML 包含以下内容，

<root>
    <entry>
        <type>U</type>
        <value>111</value>
    </entry>
    <entry>
        <type>X</type>
        <value>222</value>
    </entry>
    <entry>
        <type>E</type>
        <value>333</value>
    </entry>
    <entry>
        <type>Q</type>
        <value>444</value>
    </entry>
</root>

输出我需要， <ROOT> <ENTRY> <SLNO>1</SLNO> <VALUE>111</VALUE> </ENTRY> <ENTRY> <VALUE>222</VALUE> </ENTRY> <ENTRY> <VALUE>333</VALUE> </ENTRY> <ENTRY> <SLNO>2</SLNO> <VALUE>444</VALUE> </ENTRY> </ROOT>

我需要解析所有记录，但需要为类型不是 X 和 E 的记录输入序列号。

我已经为相同的内容编写了一个 for-each 并使用 'position()' 来显示带有 E 和 X 类型条件的序列号。所以我得到序列号为 1、4 而不是 1、2 因为 '位置（）'。

我想创建一个全局变量并在我的 if 块中增加它，但是 XSLT 1.0 不允许增加变量值。

我怎样才能做到这一点？

我的示例 XSL 代码如下，

<xsl:for-each select="/ROOT/ENTRY">
    <xsl:if test="(TYPE != 'X') and (TYPE != 'E')">             
        <xsl:text><![CDATA[<SLNO>]]></xsl:text>
        <xsl:number value="position()"/>
        <xsl:text><![CDATA[</SLNO>]]></xsl:text>
    </xsl:if>
    <!-- Printing remaining values -->
</xsl:for-each>

请帮忙。

4

2 回答 2

0

您可以计算XML中前面类型元素的数量，而不是使用 position()

<xsl:value-of select="count(preceding::type[. != 'X' and . != 'E']) + 1" />

此外，您可以通过直接匹配type元素而不是entry元素来简化当前的 XSLT ，然后只需将其替换为新的slno元素。

<xsl:template match="type[. != 'X' and . != 'E']">

例如，尝试以下 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="type[. != 'X' and . != 'E']">
      <slno><xsl:value-of select="count(preceding::type[. != 'X' and . != 'E']) + 1" /></slno>
   </xsl:template>

   <xsl:template match="type" />

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

应用于您的示例 XML 时，将输出以下内容

<root>
   <entry>
      <slno>1</slno>
      <value>111</value>
   </entry>
   <entry>
      <value>222</value>
   </entry>
   <entry>
      <value>333</value>
   </entry>
   <entry>
      <slno>2</slno>
      <value>444</value>
   </entry>
</root>

请注意，我在这里使用所有小写的元素名称。我不确定您是否想将它们翻译成大写字母。

于 2012-06-07T14:51:53.577 回答
0

公认的答案是一个很好的答案，除了实现的算法具有 O(N^2) （二次）时间复杂度并且在大输入上执行非常慢。

这是具有线性时间复杂度 O(N) 的变换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:param name="pCount" select="0"/>
  <xsl:copy>
   <xsl:apply-templates select="node()[1]|@*">
     <xsl:with-param name="pCount" select="$pCount"/>
   </xsl:apply-templates>
  </xsl:copy>
  <xsl:apply-templates select="following-sibling::node()[1]">
     <xsl:with-param name="pCount" select="$pCount"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="entry[not(contains('EX', type))]">
  <xsl:param name="pCount" select="0"/>

  <xsl:copy>
   <slno><xsl:value-of select="$pCount+1"/></slno>
   <xsl:apply-templates select="node()[1]|@*">
     <xsl:with-param name="pCount" select="$pCount+1"/>
   </xsl:apply-templates>
  </xsl:copy>
  <xsl:apply-templates select="following-sibling::node()[1]">
     <xsl:with-param name="pCount" select="$pCount+1"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="type">
   <xsl:param name="pCount" select="0"/>
   <xsl:apply-templates select="following-sibling::node()[1]">
     <xsl:with-param name="pCount" select="$pCount+1"/>
   </xsl:apply-templates>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<root>
    <entry>
        <type>U</type>
        <value>111</value>
    </entry>
    <entry>
        <type>X</type>
        <value>222</value>
    </entry>
    <entry>
        <type>E</type>
        <value>333</value>
    </entry>
    <entry>
        <type>Q</type>
        <value>444</value>
    </entry>
</root>

产生了想要的正确结果：

<root>
   <entry>
      <slno>1</slno>
      <value>111</value>
   </entry>
   <entry>
      <value>222</value>
   </entry>
   <entry>
      <value>333</value>
   </entry>
   <entry>
      <slno>2</slno>
      <value>444</value>
   </entry>
</root>

说明：

  1. 使用和覆盖“细粒度身份规则”。它之所以得名，是因为模板一次仅应用于一个节点（按文档顺序）。

  2. “细粒度身份规则”被修改为包含并传递一个参数$pCount，该参数包含迄今为止达到的最大当前“序列号”。

  3. 这无需返回当前序列号即可工作，因为所有entry元素都是同级元素。

  4. 时间复杂度是线性的，因为在每个节点上都没有计算所有先前的兄弟姐妹，就像在另一个答案中所做的那样。

于 2012-06-08T03:37:42.503 回答