7

我有这样的 XML：

<Artist name="Syd Mead" id="3412" ntrack="28" pop="8"/>

我需要在 HTML 标记中使用：

<a href="#" data-name="Syd Mead" data-id="3412"
  data-ntrack="28" data-pop="8"
  class="pop-8"><span>Syd Mead</span></a>

对于最广泛的浏览器，执行此操作的“正确”方法是什么？这可以通过 XSLT 转换可靠地完成吗？使用正则表达式（不太可能）更好还是我必须解析出xml，并为每个<Artist>标签读取每个属性并手动执行document.createElement和setAttribute？

标签位于父节点中，其中<Artist>有很多。对此有最佳做法吗？

4

3 回答 3

5

这看起来像是 XSLT 的完美候选 - XML 干净且格式良好。如果您担心浏览器兼容性，为什么不在服务器端进行转换呢？

此 XSLT 将转换您的数据 - 您可以在此处对其进行测试：

源数据：

<Artists>
    <Artist name="Syd Mead" id="3412" ntrack="28" pop="8"/>
</Artists>

XSLT：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
    <xsl:for-each select="Artists/Artist">
        <a href="#">
            <xsl:attribute name="data-id">      
                <xsl:value-of select="@id"/>
            </xsl:attribute>
            <xsl:attribute name="data-ntrack">      
                <xsl:value-of select="@ntrack"/>
            </xsl:attribute>
            <xsl:attribute name="data-pop">      
                <xsl:value-of select="@pop"/>
            </xsl:attribute>
            <xsl:attribute name="data-name">      
                <xsl:value-of select="@name"/>
            </xsl:attribute>
           <xsl:attribute name="class">    
                <xsl:value-of select="concat('pop-',@pop)"/>
           </xsl:attribute>

            <span><xsl:value-of select="@name"/></span>
        </a>
    </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

我还没有在客户端这样做，所以很遗憾我不能谈论浏览器的兼容性。

于 2012-06-07T05:28:09.063 回答
5

这是一个简单的（没有条件，没有额外的模板，没有xsl:attribute，没有xsl:for-each），简短而完整的转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="no"/>

 <xsl:template match="Artist">
     <a href="#" data-name="{@name}"
                 data-id="{@id}"
                 data-ntrack="{@ntrack}"
                 data-pop="{@pop}"
                 class="pop-{@pop}">
    <span><xsl:value-of select="@name"/></span>
  </a>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Artist name="Syd Mead" id="3412" ntrack="28" pop="8"/>

产生了想要的正确结果：

<a href="#" data-name="Syd Mead" data-id="3412" data-ntrack="28" data-pop="8" class="pop-8"><span>Syd Mead</span></a>

说明：正确使用AVT（属性值模板）

于 2012-06-07T12:36:04.243 回答
2

这是另一个在我看来更简单的 XSLT 样式表选项：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html"/>

    <xsl:template match="/*/Artist">
        <a href="#" class="pop-{@pop}"> 
            <xsl:apply-templates select="@*"/>
            <span><xsl:value-of select="@name"/></span>
        </a>        
    </xsl:template>

    <xsl:template match="@*">
        <xsl:attribute name="data-{name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

XML 输入

<Artists>
    <Artist name="Syd Mead" id="3412" ntrack="28" pop="8"/> 
</Artists>

HTML 输出

<a class="pop-8" href="#" data-name="Syd Mead" data-id="3412" data-ntrack="28" data-pop="8">
  <span>Syd Mead</span>
</a>
于 2012-06-07T06:51:11.160 回答