5

我带着另一个问题回来了。我有一个数据列表：

1 L DIELTQSPE H EVQLQESDAELVKPGASVKISCKASGYTFTDHE
2 L DIVLTQSPRVT H EVQLQQSGAELVKPGASIKDTY
3 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAN
4 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAG
5 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C LELDKWASL
6 L DIQMTQIPSSLSASLSIC H EVQLQQSGVEVKMSCKASGYTFTS
7 L SYELTQPPSVSVSPGSIT H QVQLVQSAKGSGYSFS P YNKRKAFYTTKNIIG
8 L SYELTQPPSVSVSPGRIT H EVQLVQSGAASGYSFS P NNTRKAFYATGDIIG
9 A MPIMGSSVAVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
10 A MPIMGSSVVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
11 L DVVMTQTPLQ H EVKLDESVTVTSSTWPSQSITCNVAHPASSTKVDKKIE
12 A DIVMTQSPDAQYYSTPYSFGQGTKLEIKR

我想比较每行的第 3 个元素 && 第 5 个元素，如果它们具有相同的第 3 个 && 第 5 个元素，则将它们分组。例如，使用上面的数据，结果将是：

3: 3 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAN
   4 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAG
   5 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C LELDKWASL
9: 9 A MPIMGSSVAVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
   10 A MPIMGSSVVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP

仅供参考，在实际数据中，第 3、5、7 个元素很长。我已经把它们剪下来看看整体。

这就是我所做的，我知道这很笨拙，但是作为初学者，我正在尽力而为。问题是它只显示第一组“相同”组。你能告诉我哪里出了问题和/或其他漂亮的方法来解决这个问题吗？

my $file = <>;
open(IN, $file)|| die "no $file: $!\n";
my @arr;
while (my $line=<IN>){
        push @arr, [split (/\s+/, $line)] ;
}
close IN;

my (@temp1, @temp2,%hash1);
for (my $i=0;$i<=$#arr ;$i++) {
    push @temp1, [$arr[$i][2], $arr[$i][4]]; 
    for (my $j=$i+1;$j<=$#arr ;$j++) {
        push @temp2, [$arr[$j][2], $arr[$j][4]];
        if (($temp1[$i][0] eq $temp2[$j][0])&& ($temp1[$i][1] eq $temp2[$j][1])) {
            push @{$hash1{$arr[$i][0]}}, $arr[$i], $arr[$j];
        }
    }
}
print Dumper \%hash1;
4

5 回答 5

2

你似乎把它复杂化了一点，但这对于初学者来说很常见。更多地考虑如何手动执行此操作：

  • 看每一行。
  • 查看第三个和第五个字段是否与上一行相同。
  • 如果是这样，请打印它们。

循环和所有这些都是完全不必要的：

#!/usr/bin/env perl

use strict;
use warnings;

my ($previous_row, $third, $fifth) = ('') x 3;

while (<DATA>) {
  my @fields = split;
  if ($fields[2] eq $third && $fields[4] eq $fifth) {
    print $previous_row if $previous_row;
    print "\t$_";
    $previous_row = '';
  } else {
    $previous_row = $fields[0] . "\t" . $_;
    $third = $fields[2];
    $fifth = $fields[4];
  }
}

__DATA__
1 L DIELTQSPE H EVQLQESDAELVKPGASVKISCKASGYTFTDHE
2 L DIVLTQSPRVT H EVQLQQSGAELVKPGASIKDTY
3 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAN
4 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAG
5 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C LELDKWASL
6 L DIQMTQIPSSLSASLSIC H EVQLQQSGVEVKMSCKASGYTFTS
7 L SYELTQPPSVSVSPGSIT H QVQLVQSAKGSGYSFS P YNKRKAFYTTKNIIG
8 L SYELTQPPSVSVSPGRIT H EVQLVQSGAASGYSFS P NNTRKAFYATGDIIG
9 A MPIMGSSVAVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
10 A MPIMGSSVAVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
11 L DVVMTQTPLQ H EVKLDESVTVTSSTWPSQSITCNVAHPASSTKVDKKIE
12 A DIVMTQSPDAQYYSTPYSFGQGTKLEIKR

（请注意，我稍微更改了第 10 行，使其第三个字段与第 9 行匹配，以便在输出中获得指定的相同组。）

编辑：一行代码因复制/粘贴错误而重复。

编辑2：作为对评论的回应，这是第二个版本，它不假定应该分组的行是连续的：

#!/usr/bin/env perl

use strict;
use warnings;

my @lines;
while (<DATA>) {
  push @lines, [ $_, split ];
}

# Sort @lines based on third and fifth fields (alphabetically), then on
# first field/line number (numerically) when third and fifth fields match
@lines = sort { 
  $a->[3] cmp $b->[3] || $a->[5] cmp $b->[5] || $a->[1] <=> $b->[1] 
} @lines;

my ($previous_row, $third, $fifth) = ('') x 3;
for (@lines) {
  if ($_->[3] eq $third && $_->[5] eq $fifth) {
    print $previous_row if $previous_row;
    print "\t$_->[0]";
    $previous_row = '';
  } else {
    $previous_row = $_->[1] . "\t" . $_->[0];
    $third = $_->[3];
    $fifth = $_->[5];
  }
}

__DATA__
1 L DIELTQSPE H EVQLQESDAELVKPGASVKISCKASGYTFTDHE
3 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAN
2 L DIVLTQSPRVT H EVQLQQSGAELVKPGASIKDTY
5 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C LELDKWASL
7 L SYELTQPPSVSVSPGSIT H QVQLVQSAKGSGYSFS P YNKRKAFYTTKNIIG
6 L DIQMTQIPSSLSASLSIC H EVQLQQSGVEVKMSCKASGYTFTS
9 A MPIMGSSVAVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
8 L SYELTQPPSVSVSPGRIT H EVQLVQSGAASGYSFS P NNTRKAFYATGDIIG
11 L DVVMTQTPLQ H EVKLDESVTVTSSTWPSQSITCNVAHPASSTKVDKKIE
10 A MPIMGSSVAVLAIL B DIVMTQSPTVTI C EVQLQQSGRGP
12 A DIVMTQSPDAQYYSTPYSFGQGTKLEIKR
4 A ALQLTQSPSSLSAS B RITLKESGPPLVKPTCS C ELDKWAG
于 2012-06-05T13:50:09.207 回答
1

略有不同的做法：

#!/usr/bin/perl

use strict;
use warnings;

my %lines; # hash with 3rd and 5th elements as key
my %first_line_per_group; # stores in which line a group appeared first

while(my $line = <>) {
    # remove line break
    chomp $line;

    # retrieve elements form line
    my @elements = split /\s+/, $line;

    # ignore invalid lines
    next if @elements < 5;

    # build key from elements 3 and 5 (array 0-based!)
    my $key = $elements[2] . " " . $elements[4];

    if(! $lines{key}) {
        $first_line_per_group{$key} = $elements[0];
    }

    push @{ $lines{$key} }, $line;
}


# output
for my $key (keys %lines) {
    print $first_line_per_group{$key} . ":\n";

    print "    $_\n" for @{ $lines{$key} };
}
于 2012-06-05T13:53:32.710 回答
1

例子：

use strict;
use warnings;

{ ... }

open my $fh, '<', $file or die "can't open $file: $!";

my %hash;

# read and save it
while(my $line = <$fh>){
    my @line = split /\s+/, $line;
    my $key = $line[2] . ' ' . $line[4];

    $hash{$key} ||= [];
    push @{$hash{$key}}, $line; 
}

# remove single elements
for my $key (keys %hash){
    delete $hash{$key} if @{$hash{$key}} < 2;
}

print Dumper \%hash;
于 2012-06-05T13:45:38.227 回答
0

Your approach shows a pretty solid grasp of Perl idiom and has merit, but still is not how I would do it.

I think that you will have an easier time with this if you structure your data slightly differently: Let %hash1 be something like

(
    'ALQLTQSPSSLSAS' => {
        'RITLKESGPPLVKPTCS' => [3, 4, 5],
        'ABCXYZ' => [93, 95, 96],
    },
    'MPIMGSSVAVLAIL' => {
        'DIVMTQSPTVTI' => [9, 10],
    },
)

where I have added a datum ABCXYZ which is not in your example to show the data structure in its fullness.

于 2012-06-05T13:44:52.793 回答
0

您应该使用 open() 的 3 参数形式，并且可以简化数据的读取：

open my $fh, '<', $file
    or die "Cannot open '$file': $!\n";

chomp(my @rows = <$fh>);
@rows = map {[split]} @rows;

close $fh;

要对行进行分组，您可以使用将第 3 个和第 5 个字段连接为键的散列。编辑：您必须添加一个分隔字符以消除“如果不同的行产生相同的连接”（Qtax）的无效结果。附加数据，例如单个数据行的数量，可以存储为散列值。这里存储了行的字段：

my %groups;
for (@rows) {
    push @{ $groups{$_->[2] . ' ' . $_->[4]} }, $_
        if @$_ >= 4;
}

对单个元素进行排序：

@{ $groups{$_} } < 2 && delete $groups{$_}
    for keys %groups;

问候，马蒂亚斯

于 2012-06-05T14:09:29.320 回答