3

我有以下事实和规则：

% frequents(D,P) % D=drinker, P=pub
% serves(P,B) % B=beer
% likes(D,B)

frequents(janus, godthaab).
frequents(janus, goldenekrone).
frequents(yanai, goldenekrone).
frequents(dimi,  schlosskeller).

serves(godthaab, tuborg).
serves(godthaab, carlsberg).
serves(goldenekrone, pfungstaedter).
serves(schlosskeller, fix).

likes(janus, tuborg).
likes(janus, carlsberg).

count_good_beers_for_at(D,P,F) :- group_by((frequents(D,P), serves(P,B), likes(D,B)),[D,P],(F = count)).
possible_beers_served_for_at(D,P,B) :- lj(serves(P,B), frequents(D,R), P=R).

现在，我想构建一个规则，当“饮酒者”“频率”大于 0 的每个酒吧中可用的“喜欢”啤酒的数量时，该规则应该像返回“真”的谓词一样工作。

当规则不返回元组时，我会认为谓词为真。如果谓词为假，我打算让它返回没有单一“喜欢”啤酒的酒吧。

正如你所看到的，我已经有一个规则来计算给定酒吧中给定饮酒者的好啤酒。我还有一条规则，告诉我可供应啤酒的数量。

DES> count_good_beers_for_at(A,B,C)

{                                           
  count_good_beers_for_at(janus,godthaab,2)
}
Info: 1 tuple computed.

如您所见，柜台不会返回经常光顾的酒吧，但有 0 个喜欢的啤酒。我打算通过使用左外连接来解决这个问题。

DES> is_happy_at(D,P,Z) :- lj(serves(P,B), count_good_beers_for_at(D,Y,Z), (Y=P))

Info: Processing:
  is_happy_at(D,P,Z) :-
    lj(serves(P,B),count_good_beers_for_at(D,Y,Z),Y = P).
{                                           
  is_happy_at(janus,godthaab,2),
  is_happy_at(null,goldenekrone,null),
  is_happy_at(null,schlosskeller,null)
}
Info: 3 tuples computed.

这几乎是对的，除了它也给了我不常去的酒吧。我尝试添加一个额外的条件：

DES> is_happy_at(D,P,Z) :- lj(serves(P,B), count_good_beers_for_at(D,Y,Z), (Y=P)), frequents(D,P)

Info: Processing:
  is_happy_at(D,P,Z) :-
    lj(serves(P,B),count_good_beers_for_at(D,Y,Z),Y = P),
    frequents(D,P).
{                                           
  is_happy_at(janus,godthaab,2)
}
Info: 1 tuple computed.

现在我以某种方式过滤掉了所有包含空值的东西！我怀疑这是由于 DES 中的空值逻辑造成的。

我认识到我可能以错误的方式处理整个问题。任何帮助表示赞赏。

编辑：作业是“very_happy(D) ist wahr, genau dann wenn jede Bar, die Trinker D besucht, wenigstens ein Bier ausschenkt, das er mag。” 转换为“ very_happy(D) 是真的，如果每个酒吧饮酒者 D 访问，至少提供 1 杯他喜欢的啤酒”。由于这个作业是关于 Datalog 的，我认为不使用 Prolog 绝对可以解决。

4

2 回答 2

4

我认为对于您的分配，您应该使用基本的 Datalog，而不要滥用聚合。问题的关键是如何表达普遍量化的条件。我搜索了“通用量化数据日志”，在第一个位置我发现deductnotes.pdf断言：

一个普遍量化的条件只能用存在量化和否定的等价条件来表示。

在该 PDF 中，您还会发现一个有用的示例（第 9 和第 10 页）。

因此，我们必须重新表述我们的问题。我最终得到了这段代码：

not_happy(D) :-
  frequents(D, P),
  likes(D, B),
  not(serves(P, B)).

very_happy(D) :-
  likes(D, _),
  not(not_happy(D)).

这似乎是需要的：

DES> very_happy(D)

{                                           
}
Info: 0 tuple computed.

请注意likes(D, _)，这是避免 yanai 和 dimi 被列为very_happy 所必需的，而没有明确断言他们喜欢什么（抱歉，我的英语真的很烂......）

编辑：对不起，但上述解决方案不起作用。我用这种方式重写了它：

likes_pub(D, P) :-
  likes(D, B),
  serves(P, B).

unhappy(D) :-
  frequents(D, P),
  not(likes_pub(D, P)).

very_happy(D) :-
  likes(D, _),
  not(unhappy(D)).

测试：

DES> unhappy(D)

{                                           
  unhappy(dimi),
  unhappy(janus),
  unhappy(yanai)
}
Info: 3 tuples computed.          

DES> very_happy(D)

{                                           
}
Info: 0 tuples computed.

现在我们添加一个事实：

serves(goldenekrone, tuborg).

我们可以看到更正后的代码结果：

DES> unhappy(D)

{                                           
  unhappy(dimi),
  unhappy(yanai)
}
Info: 2 tuples computed.          

DES> very_happy(D)

{                                           
  very_happy(janus)
}
Info: 1 tuple computed.
于 2012-06-07T19:17:16.420 回答
2

也许不是您期望的答案。但是您可以使用普通的 Prolog 并使用 bagof/3 或 setof/3 内置谓词轻松地进行分组查询。

?- bagof(B,(frequents(D,P), serves(P,B), likes(D,B)),L), length(L,N).
D = janus,
P = godthaab,
L = [tuborg,carlsberg],
N = 2

bagof/3 的语义使得它不会为给定的查询计算外连接。查询通常由 Prolog 执行。结果首先被累加和键排序。最后通过回溯返回结果。如果您的数据记录不能没有空值，那么是的，您必须进行过滤。

但是当您只想知道喜欢的啤酒的存在时，您不需要进行聚合。您可以通过查询直接执行此操作，无需任何聚合：

is_happy_at(D,P) :- frequents(D,P), once((serves(P,B), likes(D,B))).
?- is_happy_at(D,P).
D = janus,
P = godthaab ;
Nein

once/1 防止不必要的回溯。当 Datalog 在 is_happy_at/2 中看到投影时，Datalog 可能会自动不进行不必要的回溯，即 B 被投影掉。或者您可能需要显式使用与 SQL DISTINCT 对应的内容。或者最终，您的数据日志为您提供了与 SQL EXISTS 最接近的对应于一次/1 的内容。

再见

于 2012-06-07T09:20:37.977 回答