1

通过 ADO，我喜欢做以下查询：

    select name, address, zip from terr where id = '33334'

然后我喜欢将名称、地址、zip 分配给变量，以便稍后在我的程序中分配它。如何使用 VB.NET ADO 执行此操作？

4

4 回答 4

8

尝试这样的事情：

  Dim dbName As String
  Dim dbAddress As String
  Dim dbZip As String
  Using connObj As New SqlClient.SqlConnection("<connectionString>")
     Using cmdObj As New SqlClient.SqlCommand("select name, address, zip from terr where id = '33334'", connObj)
        connObj.Open()
        Using readerObj As SqlClient.SqlDataReader = cmdObj.ExecuteReader
           'This will loop through all returned records 
           While readerObj.Read
              dbName = readerObj("name").ToString
              dbAddress = readerObj("address").ToString
              dbZip = readerObj("zip").ToString
              'handle returned value before next loop here
           End While
        End Using
        connObj.Close()
     End Using
  End Using

此外，您应该考虑参数化 where 子句的值。

于 2012-06-01T20:17:33.757 回答
2

你需要一个数据库（我假设是 MS Sql-Server）、一个连接和一个 DataAdapter 来填充一个 DataTable。然后你就拥有了你需要的一切。这是一个例子：

Public Function GetUser(UserId As Int32) As DataRow
    Using con = New SqlConnection(My.Settings.RM2ConnectionString)
        Using cmd = New SqlCommand("select name, address, zip from terr where id = @id", con)
            cmd.Parameters.AddWithValue("@id", UserId)
            Dim da = New SqlDataAdapter(cmd)
            Dim tblUser = New DataTable
            da.Fill(tblUser)
            If tblUser.Rows.Count <> 0 Then
                Return tblUser(0)
            Else
                Return Nothing
            End If
        End Using
    End Using
End Function
于 2012-06-01T20:13:22.140 回答
0

从 SQLDatareader 执行 SqlCommand，例如：

Dim vVendedor As New SqlCommand("SELECT user FROM users", mConeccion)
vDatosVen = vVendedor.ExecuteReader
vVendedor = Nothing

并获得 te 值：

While vDatosVen.Read() 
   vUser = vDatosVen("user")
End While
于 2012-06-01T20:18:20.770 回答
0

这就是我所做的...

   Private Sub btn_Connect_Click(sender As Object, e As EventArgs) Handles btn_Connect.Click
    Dim sql_connection As New MySqlConnection
    Dim sql_query As New MySqlCommand
    Dim sql_result As MySqlDataReader
    sql_connection.ConnectionString = "Server=localhost;Database=hidden;Uid=root;Pwd=;"
    sql_query.Connection = sql_connection
    sql_connection.Open()
    sql_query.CommandText = "SELECT Entry,name FROM table WHERE entry=1;"
    sql_result = sql_query.ExecuteReader
    If sql_result.HasRows Then

        Do While sql_result.Read()
            Dim query_result As String
            query_result = sql_result("name")
            MsgBox(query_result)
        Loop
    Else
        MsgBox("No results found.")
    End If
于 2017-02-20T19:11:08.377 回答