51

我正在尝试创建自动安装 zend 服务器 CE 的 puppet 模块，这在这里并不重要，但步骤如下

  1. 更新 /etc/apt/source.list
  2. 通过 wget 下载 repos 密钥
  3. 做apt-get更新
  4. 做 apt-get install zend-server-ce-5.2

我有init.pp档案

class zendserverce {

# https://github.com/puppetlabs/puppetlabs-stdlib
file_line { 'debian_package':
    path => '/etc/apt/sources.list',
    line => 'deb http://repos.zend.com/zend-server/deb server non-free'
}

exec { "wget http://repos.zend.com/zend.key -O- |apt-key add -":
    path => ["/usr/bin", "/usr/sbin"]
}

exec { "apt-get update":
    command => "/usr/bin/apt-get update",
    onlyif  => "/bin/sh -c '[ ! -f /var/cache/apt/pkgcache.bin ] || /usr/bin/find /etc/apt/* -cnewer /var/cache/apt/pkgcache.bin | /bin/grep . > /dev/null'",
}

package { "zend-server-ce-php-5.2":
    ensure => "latest"
}

}

似乎 puppet 以不同的顺序运行命令，然后我需要。有什么办法可以告诉他按照我想要的顺序运行？

这种片段的输出是

  [0;36mnotice: /Stage[main]/Mc/Package[mc]/ensure: ensure changed 'purged' to 'latest'[0m
  [1;35merr: /Stage[main]/Zendserverce/Package[zend-server-ce-php-5.2]/ensure: change from purged to latest failed: Could not update: Execution of '/usr/bin/apt-get -q -y -o DPkg::Options::=--force-confold install zend-server-ce-php-5.2' returned 100: Reading package lists...
  Building dependency tree...
  Reading state information...
  E: Couldn't find package zend-server-ce-php-5.2 at /tmp/vagrant-puppet/modules 0/zendserverce/manifests/init.pp:28[0m
  [0;36mnotice: /Stage[main]/Zendserverce/Exec[wget http://repos.zend.com/zend.key -O- |apt-key add -]/returns: executed successfully[0m
  [0;36mnotice: /Stage[main]/Zendserverce/File_line[debian_package]/ensure: created[0m
  [0;36mnotice: Finished catalog run in 6.75 seconds[0m

所以它说：找不到包zend-server-ce-php-5.2

谁能指导我出了什么问题？

4

8 回答 8

101

从 Puppet 2.6.0 开始，引入了一个新特性“关系语法” 。

Puppet 2.6.0 及更高版本中的示例如下所示：

exec { "apt-update":
    command => "/usr/bin/apt-get update"
}

Exec["apt-update"] -> Package <| |>

每次执行 package 命令时，依赖项（在我们的例子中是 'apt-update'）都会被触发。您甚至可以定义更长的链。

于 2012-12-01T00:43:57.423 回答
51

您需要指定依赖关系。最简单/最干净的方法是使用可用于所有资源类型的 require 参数。

package { "zend-server-ce-php-5.2":
  ensure  => latest,
  require  => Exec['apt-get update'],
}

ETC..

于 2012-06-01T19:06:08.413 回答
13

我尝试了以前的变体，但它在 Ubuntu 10.04 上对我不起作用

最后，我准备了以下脚本，每次存储库超过一周时都会运行更新：

exec { 'apt-get update':
    command => "/usr/bin/apt-get update",
    onlyif => "/bin/bash -c 'exit $(( $(( $(date +%s) - $(stat -c %Y /var/lib/apt/lists/$( ls /var/lib/apt/lists/ -tr1|tail -1 )) )) <= 604800 ))'"
}

希望能帮助到你。

于 2013-02-07T14:59:15.393 回答
12

我更喜欢将 apt-upgrade 放在主阶段之前运行的单独阶段，因此我不必硬连线任何依赖项。在这里查看：http: //docs.puppetlabs.com/puppet/2.7/reference/lang_run_stages.html。

一个简单的例子如下所示。这意味着您有一个单独的类来执行实际的 apt-update：

stage { "init": before  => Stage["main"] }

class {"apt-update": 
  stage => init, 
  apt_mirror => $apt_mirror 
}

检查我在 github 上的示例 LAMPP-box，看看这些部分是如何组合在一起的：https ://github.com/joerx/vagrant-lampp

注意：使用 apt-upgrade 时要小心，因为一些基础盒会因内核升级等原因而损坏。

于 2013-09-03T03:34:08.263 回答
4

在 Puppet 3 中，这可以通过使用资源收集器实现虚拟资源来完成

# so you don't have to fully qualify paths to binaries
Exec { path => ['/usr/bin'] }    

# virtual resource
@exec { 'sudo apt-get update':
   tag => foo_update
}

# realize resource. filter by arbitrary "foo_update"
# tag and relate it to all Package resources
Exec <| tag == foo_update |> -> Package <| |>
于 2013-05-19T23:00:02.083 回答
3

添加这段巫毒教对我们有用：

  Apt::Pin <| |> -> Package <| |>
  Apt::Source <| |> -> Package <| |>

这迫使更新。YMMV。

于 2014-07-16T16:23:08.343 回答
1

需要更新 APT 列表的软件包应该需要Class['apt::update']

package { "zend-server-ce-php-5.2":
   ensure => "latest",
   require => Class['apt::update']
}

如果您使用自定义 APT 源，请确保正确排序：

Apt::Source['my_source'] 
-> Class['apt::update']
于 2017-04-29T23:49:44.447 回答
0

你真的应该使用 apt 模块来创建源和添加密钥：https ://forge.puppet.com/puppetlabs/apt

如果您使用的是 hiera：

apt::sources:
  'artifactory-pro-debs':
    location: 'http://repos.zend.com/zend-server/deb'
    release: 'server
    repos: 'non-free'
    key:
      source: 'http://repos.zend.com/zend.key'
于 2019-05-03T15:51:06.740 回答