7

我正在努力实现 sha-256 算法。我对消息的填充有问题。对于 sha-256，您必须在消息的末尾附加一个位，到目前为止我已经达到了$message .= (chr 0x80); 下一步应该是用 0 填充 emtpy 空间（512 位块）。我用这个公式计算它：l+1+k=448-l 然后将它附加到消息中。现在我的问题来了：在最后一个 64 位块中附加消息长度的二进制表示，并再次用 0 填充其余部分。由于 perl 自己处理它们的数据类型，所以没有“字节”数据类型。我怎样才能确定我应该附加哪个值？

另请参阅官方规范： http ://csrc.nist.gov/publications/fips/fips180-3/fips180-3_final.pdf

4

2 回答 2

5

首先，我希望你把它作为一个练习——Digest核心中有一个模块已经可以很好地计算 SHA-256。

请注意，$message .= (chr 0x80);附加一个字节，而不是一位。如果您真的需要按位操作，请查看该vec函数。

要获得整数的二进制表示，您应该使用pack。要使其达到 64 位，请执行以下操作

$message .= pack 'Q', length($message)

请注意，“Q”格式仅适用于 64 位 perls；如果您的不是一个，只需将四个 0 字节与一个 32 位值（包格式L）连接起来。

于 2012-05-31T10:02:53.697 回答
5

如果可能的话，把一些东西从架子上拿下来。您不想推出自己的 SHA-256 实现，因为要获得官方的祝福，您必须对其进行认证。

也就是说，规范是

5.1.1 SHA-1、SHA-224 和 SHA-256

假设消息的长度M为l位。将该位附加1到消息的末尾，后跟k个零位，其中k是方程的最小非负解

l + 1 + k ≡ 448 mod 512

然后附加等于使用二进制表示表示的数字l的 64 位块。例如，（8 位 ASCII）消息“<strong>abc”的长度为 8 × 3 = 24，因此该消息用一位填充，然后是 448 - (24 + 1) = 423 个零位，然后消息长度，成为 512 位填充消息

                                  423       64
                                 .-^-.  .---^---.
01100001  01100010  01100011  1  00…00  00…011000
   “a”       “b”       “c”                  '-v-'
                                             l=24

那么填充消息的长度现在应该是 512 位的倍数。

您可能很想使用vec它，因为它允许您寻址单个位，但您必须解决时髦的寻址问题。

如果位为 4 或更少，则将字符串分解为字节，然后将每个字节的位分解为 8/ BITS组。字节的位以 little-endian-ish 方式编号，如0x01, 0x02, 0x04, 0x08, 0x10, 0x20, 0x40, 0x80。例如，将单个输入字节chr(0x36)分成两组给出一个列表(0x6, 0x3)；把它分成 4 组给出(0x2, 0x1, 0x3, 0x0)。

相反，pack模板B*指定

一个位串（每个字节内的降序位顺序）。

和N

“网络”（大端）顺序的无符号长整数（32 位）。

后者对于组装消息长度很有用。虽然pack有Qquad的参数，但结果是本机顺序。

从一些准备工作开始

our($UPPER32BITS,$LOWER32BITS);
BEGIN {
  use Config;
  die "$0: $^X not configured for 64-bit ints"
    unless $Config{use64bitint};

  # create non-portable 64-bit masks as constants
  no warnings "portable";
  *UPPER32BITS = \0xffff_ffff_0000_0000;
  *LOWER32BITS = \0x0000_0000_ffff_ffff;
}

然后你可以定义pad_message为

sub pad_message {
  use bytes;

  my($msg) = @_;
  my $l = bytes::length($msg) * 8;
  my $extra = $l % 512;  # pad to 512-bit boundary
  my $k = 448 - ($extra + 1);

  # append 1 bit followed by $k zero bits
  $msg .= pack "B*", 1 . 0 x $k;

  # add big-endian length
  $msg .= pack "NN", (($l & $UPPER32BITS) >> 32), ($l & $LOWER32BITS);

  die "$0: bad length: ", bytes::length $msg
    if (bytes::length($msg) * 8) % 512;

  $msg;
}

假设代码打印填充消息

my $padded = pad_message "abc";

# break into multiple lines for readability
for (unpack("H*", $padded) =~ /(.{64})/g) {
  print $_, "\n";
}

然后输出是

616263800000000000000000000000000000000000000000000000000000000000
000000000000000000000000000000000000000000000000000000000000000018

符合规范。

于 2012-05-31T19:58:03.220 回答