autohotkey - 有人可以帮我一个 AutoHotKey 脚本吗？

Question

我已经阅读了它的帮助和指南，但我就是想不通。我想要做的就是创建一个热键，当按下它时会移动我的鼠标，直到再次按下热键。谁能告诉我该怎么做？它应该很简单，但显然我错过了一些东西。

Answer 1

这几乎是有史以来最烦人的热键，但你去吧（热键是Ctrl++ Alt）C；

#MaxThreadsPerHotkey 3
^!c::
#MaxThreadsPerHotkey 1
if DoMouseMove
{
   DoMouseMove := false
   return
}

DoMouseMove := true
Loop
{
   Sleep 100
   Random, randX, 1, 1028
   Random, randY, 1, 800
   MouseMove, randX, randY, 25
   Sleep, 100

   if not DoMouseMove 
      break
}
DoMouseMove := false
return

Answer 2

我会提出我的解决方案。

pause::
If (Toggle := !Toggle) ; Toggle the value True/False
    {
        ToolTip Mouse Mover,A_ScreenWidth/2,0 ; Show that Mouse Mover is active
        SetTimer MoveMouse, 1000 ; 1000 ms = 1 sec. Every minute (60000 ms) is probably enough.
    }
Else
    {
        Tooltip ;  Turn Mouse Mover alert window off
        SetTimer MoveMouse, Off ; Turn the timer off
    }
return

MoveMouse:
    MouseMove, 1, 0, 1, R ;Move the mouse one pixel to the right
    Sleep, 50 ; Wait 50 ms. Not realy required, but makes the move visible
    MouseMove, -1, 0, 1, R ;Move the mouse back one pixel
return