3

我的xml：要转换的输入xml

                 <content>    
                     <conditionalText name="Masked_Account_Number">
                          <text>
                             Hi 2<dynamicVariable name="asked_Account"/> is needed.
                         </text>
                     </conditionalText>

                     <dynamicInclude name="xyz" />
                </content>

所以我必须使用上面的xml，识别所有包含'name'的标签作为属性，提取它的值并创建标签'name'，在它下面，它应该有'a'标签，格式如下：

在输入 xml 中包含“名称”作为其属性的所有标签的转换输出应为：

                             <name>
                                <a href="#" id="dynamicvariable" 
                                   name="value of name attribute"                   
                                   xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                                </a>
                          </name>

并且仅对于输入 xml 文件的“dynamicVariable”标签，它应该只创建“a”标签作为

输入 xml 的“dynamicVariable”标签的转换输出应如下所示：

                      <a href="#" id="dynamicvariable" 
                                name="value of name attribute"                   
                            xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                      </a>

所以转换后我的输出xml应该看起来像

           <content1>
                     <conditionalText>
                         <text>
                           Hi 2
                           <a href="#" id="dynamicvariable" 
                               name="asked_Account"                   
                               xmlns="http://www.w3.org/1999/xhtml">[asked_Account]
                           </a>is needed
                        </text>

                         <name>
                           <a href="#" id="dynamicvariable"                                 
                             name="Masked_Account_Number"                   
                             xmlns="http://www.w3.org/1999/xhtml">[Masked_Account_Number]
                           </a>
                        </name>
                  </conditionalText>

                  <dynamicInclude>
                      <name>
                         <a href="#" id="dynamicvariable" name="xyz"                   
                            xmlns="http://www.w3.org/1999/xhtml">[xyz]
                         </a>
                     </name>
                  </dynamicIncude>
          </content1>

XSLT 尝试如下： 我采用了两个模板。第一个模板将识别所有包含“名称”的标签作为它们的属性并提取它的值并以格式创建为

                                 <name>
                                  <a href="#" id="dynamicvariable" 
                                    name="value of name attribute"                   
                                   xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                                  </a>
                                </name>

第二个模板将覆盖第一个模板，它将仅识别名称为“dynamicVariable”的标签并提取其“名称”属性值并创建格式为的标签

                            <a 
                              href="#" id="dynamicvariable" 
                              name="value of name attribute"                   
                             xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                            </a>

所以我的最终xslt如下：

                  <?xml version="1.0" encoding="utf-8"?>
           <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
             <xsl:output method="xml" indent="yes"/>

               <xsl:template match="content/*">
                    <content1>
                      <xsl:apply-templates />
                    </content1>
              </xsl:template>

           <xsl:template  match= "*/@name" >
                   <name>
                      <a href ='#'  id="dynamicvariable" xmlns="http://www.w3.org/1999/xhtml" >
                          <xsl:copy-of select="@*"/>
                              [<xsl:value-of select="@name"/>]
                      </a>
                  </name>

                 <xsl:for-each select="child::*">
                    <xsl:if test="name()='text'">
                          <text>
                            <xsl:apply-templates />
                           </text>
                     </xsl:if>
                  </xsl:for-each>
      </xsl:template>

                <xsl:template  match= "*[name()='dynamicVariable']" >
                  <a href ='#'  id="dynamicvariable" xmlns="http://www.w3.org/1999/xhtml" >
                     <xsl:copy-of select="@*"/>
                       [<xsl:value-of select="@name"/>]
                  </a>
                </xsl:template>

        </xsl:stylesheet>

但没有得到所需的转换后的 xml。谁能帮我吗 。并且具有条件文本元素的转换后的 xml 文件应该具有与转换后的 xml 中指定的相同顺序的子子项。

4

1 回答 1

1

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*[not(name()='name')]"/>
       <xsl:apply-templates select="@name"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*/@name">
   <name>
     <a href="#" id="dynamicvariable"
        name="{.}"
        xmlns="http://www.w3.org/1999/xhtml">[<xsl:value-of select="."/>]
     </a>
   </name>
 </xsl:template>

 <xsl:template match="dynamicVariable">
   <a href="#" id="dynamicvariable"
      name="{@name}"
      xmlns="http://www.w3.org/1999/xhtml">[<xsl:value-of select="@name"/>]
   </a>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<content>
  <conditionalText name="Masked_Account_Number">
    <text>
      Hi 2<dynamicVariable name="asked_Account"/> is needed.
    </text>
  </conditionalText>

  <dynamicInclude name="xyz" />
</content>

产生想要的（重命名content留给读者作为练习），正确的结果：

<content>
   <conditionalText>
      <text>
      Hi 2<a xmlns="http://www.w3.org/1999/xhtml" href="#" id="dynamicvariable" name="asked_Account">[asked_Account]
   </a> is needed.
    </text>
      <name>
         <a xmlns="http://www.w3.org/1999/xhtml" href="#" id="dynamicvariable" name="Masked_Account_Number">[Masked_Account_Number]
     </a>
      </name>
   </conditionalText>
   <dynamicInclude>
      <name>
         <a xmlns="http://www.w3.org/1999/xhtml" href="#" id="dynamicvariable" name="xyz">[xyz]
     </a>
      </name>
   </dynamicInclude>
</content>
于 2012-05-31T12:11:22.197 回答