regex - 字符串替换的 Perl 代码

Question

我想用其他三个子字符串（作为参数传递给我的例程）替换字符串中的子字符串“[ids]”、“[order]”和“[limit]”。

但是如果“[”或“]”前面有“\”（“\[”，“\]”），我想取消“[...]”的特殊含义。“\”也应该自行取消：“\\”表示“\”。

如何在 Perl 中实现这一点？

请注意，我们可以使用其他东西来代替“[ids]”、“[order]”和“[limit]”。这不是一成不变的。

Answer 1

为什么不使用现有的模板模块而不是发明另一个？

无论如何，这是一个可以处理您的格式的解析器。

my %replace = (
   ids => ...,
   ...
);

my $out = '';
for ($in) {
   if (/\G    ( (?: [^\\\[\]]+ | \\. )+ )    /xsgc) {
       $out .= $1;
       redo;
   }

   if (/\G \[ ( (?: [^\\\[\]]+ | \\. )+ ) \] /xsgc) {
       die if !exists($replace{$1});
       $out .= $replace{$1};
       redo;
   }

   die if !/\G\Z/xsgc;
}

Answer 2

这是您可以做到的一种方法：

sub replace{
    my ($str, $ids, $order, $limit) = @_;
    $str =~ s/(?<!\\)((?:\\.)*) \[ (?: (ids) | (order) | limit ) \]/
              $1 . ($2? $ids: $3? $order: $limit)/gsex;
    return $str;
}

例子：

print replace <<'_STR_', '<1DZ>', '<0RD3RZ>', '<L1M1TZ>';
[ids][order][limit]
\[ids]\\[ids]\\\[ids]
_STR_

输出：

<1DZ><0RD3RZ><L1M1TZ>
\[ids]\\<1DZ>\\\[ids]

Answer 3

#!/usr/bin/perl

use strict;
use warnings;

sub replace_squared_terms {
  my ($str, $hash) = @_;
  my $new = "";
  for(;;) {
    return $new if $str eq "";
    if($str =~ /^([^\[\]\\\/]+)(.*)/s) {
      $new .= $1;
      $str = $2;
    } elsif($str =~ /^\[([^\/\[\]]+)\](.*)/s) {
      die "Wrong template" unless exists $hash->{$1};
      $new .= $hash->{$1};
      $str = $2;
    } elsif($str =~ /^\\(.)(.*)/s) {
      $new .= $1;
      $str = $2;
    } else {
      die "Wrong template";
    }
  }
}

my $str = "[a] [b] \\[ [a] \\\\";
print replace_squared_terms($str, {a=>"123", b=>"XYZ"}), "\n";