sql-server - 将多条记录插入视图时，tsql 返回标识值

Question

我有一种情况，我需要将多个记录/批量插入插入到具有而不是触发器的视图中。如何检索插入的标识值？我尝试使用 OUTPUT 子句从 Inserted 表中检索 Id，但它始终返回 null。

Answer 1

使用此设置。

create table InsteadOf
(
  ID int identity primary key,
  Name varchar(10) not null
)

go

create view v_InsteadOf
as
select ID, Name
from InsteadOf

go

create trigger tr_InsteadOf on InsteadOf instead of insert
as
begin
  insert into InsteadOf(Name)
  select Name
  from inserted
end

该声明

insert into v_InsteadOf(Name)
output inserted.*
select 'Name1' union all 
select 'Name2'

会给你一个错误。

消息 334，级别 16，状态 1，第 4 行如果语句包含没有 INTO 子句的 OUTPUT 子句，则 DML 语句的目标表“InsteadOf”不能有任何启用的触发器。

而是使用带有插入的 INTO 子句。

declare @IDs table(ID int, Name varchar(10))

insert into v_InsteadOf(Name)
output inserted.* into @IDs
select 'Name1' union all 
select 'Name2'

select *
from @IDs

给你0的价值不null。

ID          Name
----------- ----------
0           Name1
0           Name2

您可以将输出子句放在触发器中。

create trigger tr_InsteadOf on InsteadOf instead of insert
as
begin
  insert into InsteadOf(Name)
  output inserted.*
  select Name
  from inserted
end

当您进行插入时，将为您生成输出。

insert into v_InsteadOf(Name)
select 'Name1' union all 
select 'Name2'

结果：

ID          Name
----------- ----------
1           Name1
2           Name2

更新：
要捕获插入语句的输出，您可以使用insert into ... exec (...)

declare @T table
(
  ID int,
  Name varchar(10)
)

insert into @T
exec
  (
    'insert into v_InsteadOf(Name)
     values (''Name1''),(''Name2'')'
  )