string - Prolog将字符串转换为对列表

Question

我正在学习 Prolog，我需要知道如何转换字符串列表：

['f(a,45)', 'f(b,13)', 'f(c,12)']

成如下所示的对列表：

[[45,'a'],[13,'b'],[12,'c']]

Answer 1

那是atom的列表，而不是字符串。Prolog 中的字符串通常是字符代码列表，表示为

["f(a,45)", "f(b,13)", "f(c,12)"]

无论如何，使用递归函数对每个元素应用转换：

convert([], []).
convert([Atom|Atoms], [Pair|Pairs]) :-
  convert_element(Atom, Pair),
  convert(Atoms, Pairs).

您可以使用maplist /3代替递归：

convert(As, Ps) :- maplist(convert_element, As, Ps).

要转换元素，您需要一个解析器。DCG 很方便：

convert_element(Atom, [N, A]) :-
  atom_codes(Atom, Codes),
  phrase(("f(", atomc(Ac), ",", numc(Nc), ")"), Codes, []),
  atom_codes(A, Ac),
  number_codes(N, Nc).

atomc(A) --> ([C], {is_lowerc(C)}, atomc(Cs), {A = [C|Cs]}) ; {A = []}.
numc(N) --> ([C], {is_numc(C)}, numc(Cs), {N = [C|Cs]}) ; {N = []}.

is_lowerc(C) :- C @>= 0'a, C @=< 0'z.
is_numc(C) :- C @>= 0'0, C @=< 0'9.

测试：

?- convert(['f(a,45)', 'f(b,13)', 'f(c,12)'],L).
L = [[45, a], [13, b], [12, c]] .

atomc//1 & numc//1 以紧凑的方式表示，但是是非常简单的递归模式匹配过程，即 atomc//1 可以是

atomc([C|Cs]) --> [C], {is_lowerc(C)}, !, atomc(Cs).
atomc([]) --> [].

Answer 2

或者，您可以使用以下代码：

convert :-
    L = ["f(a,45)", "f(b,13)", "f(c,12)"],
    maplist(extract_args,L, LA),
    writeln(LA).


extract_args(S, [A1,A2]) :-
    string_to_atom(S, A),
    term_to_atom(T, A),
    T =..[_, A2, A1].

如果你有原子，只需在 extract_args/2 中使用 term_to_atom/2。