5

当我对某些数据使用 Perl 或 C 时printf，我尝试了它们的格式来控制每列的​​宽度，比如

printf("%-30s", str);

但是当 str 包含汉字时，该列未按预期对齐。见附件图片。

我的ubuntu的charset编码是zh_CN.utf8，据我所知，utf-8编码有1~4个字节长度。汉字有3个字节。在我的测试中，我发现 printf 的格式控制将一个汉字计数为 3，但它实际上显示为 2 ascii 宽度。

所以真正的显示宽度并不是想象中的一个常数，而是一个与汉字个数有关的变量，即

Sw(x) = 1 * (w - 3x) + 2 * x = w - x

w 是预期的宽度限制，x 是汉字的个数，Sw(x) 是实际显示宽度。

所以str包含的汉字越多，显示的越短。

我怎样才能得到我想要的？数printf前的汉字？

据我所知，我猜的所有中文甚至所有宽字符都显示为2宽度，那么为什么printf将其计为3？UTF-8 的编码与显示长度无关。

4

1 回答 1

7

是的，这是printf我所知道的所有版本的问题。我在这个答案和这个答案中简要讨论了这个问题。

对于 C，我不知道有哪个库可以为您执行此操作，但如果有人拥有它，那就是 ICU。

对于 Perl，您必须使用 CPAN 中的Unicode::GCString模块来计算 Unicode 字符串将占用的打印列数。这考虑了Unicode 标准附件 #11：东亚宽度。

例如，一些代码点占用 1 列，而其他代码点占用 2 列。甚至有些根本不占用列，例如组合字符和不可见的控制字符。该类有一个columns方法可以返回字符串占用的列数。

我有一个使用它来垂直对齐 Unicode 文本的示例。它将对一堆 Unicode 字符串进行排序，包括一些具有组合字符和“宽”亚洲表意文字（CJK 字符）的字符串，并允许您垂直对齐。

样本终端输出

umenu下面包含打印对齐输出的小演示程序的代码。

您可能还对雄心勃勃的Unicode::LineBreak模块感兴趣，前面提到的Unicode::GCString类只是其中一个较小的组件。这个模块更酷，并考虑了Unicode 标准附件 #14：Unicode 换行算法。

这是小umenu演示的代码，在 Perl v5.14 上测试：

 #!/usr/bin/env perl
 # umenu - demo sorting and printing of Unicode food
 #
 # (obligatory and increasingly long preamble)
 #
 use utf8;
 use v5.14;                       # for locale sorting
 use strict;
 use warnings;
 use warnings  qw(FATAL utf8);    # fatalize encoding faults
 use open      qw(:std :utf8);    # undeclared streams in UTF-8
 use charnames qw(:full :short);  # unneeded in v5.16

 # std modules
 use Unicode::Normalize;          # std perl distro as of v5.8
 use List::Util qw(max);          # std perl distro as of v5.10
 use Unicode::Collate::Locale;    # std perl distro as of v5.14

 # cpan modules
 use Unicode::GCString;           # from CPAN

 # forward defs
 sub pad($$$);
 sub colwidth(_);
 sub entitle(_);

 my %price = (
     "γύρος"             => 6.50, # gyros, Greek
     "pears"             => 2.00, # like um, pears
     "linguiça"          => 7.00, # spicy sausage, Portuguese
     "xoriço"            => 3.00, # chorizo sausage, Catalan
     "hamburger"         => 6.00, # burgermeister meisterburger
     "éclair"            => 1.60, # dessert, French
     "smørbrød"          => 5.75, # sandwiches, Norwegian
     "spätzle"           => 5.50, # Bayerisch noodles, little sparrows
     "包子"              => 7.50, # bao1 zi5, steamed pork buns, Mandarin
     "jamón serrano"     => 4.45, # country ham, Spanish
     "pêches"            => 2.25, # peaches, French
     "シュークリーム"    => 1.85, # cream-filled pastry like éclair, Japanese
     "막걸리"            => 4.00, # makgeolli, Korean rice wine
     "寿司"              => 9.99, # sushi, Japanese
     "おもち"            => 2.65, # omochi, rice cakes, Japanese
     "crème brûlée"      => 2.00, # tasty broiled cream, French
     "fideuà"            => 4.20, # more noodles, Valencian (Catalan=fideuada)
     "pâté"              => 4.15, # gooseliver paste, French
     "お好み焼き"        => 8.00, # okonomiyaki, Japanese
 );

 my $width = 5 + max map { colwidth } keys %price;

 # So the Asian stuff comes out in an order that someone
 # who reads those scripts won't freak out over; the
 # CJK stuff will be in JIS X 0208 order that way.
 my $coll  = new Unicode::Collate::Locale locale => "ja";

 for my $item ($coll->sort(keys %price)) {
     print pad(entitle($item), $width, ".");
     printf " €%.2f\n", $price{$item};
 }

 sub pad($$$) {
     my($str, $width, $padchar) = @_;
     return $str . ($padchar x ($width - colwidth($str)));
 }

 sub colwidth(_) {
     my($str) = @_;
     return Unicode::GCString->new($str)->columns;
 }

 sub entitle(_) {
     my($str) = @_;
     $str =~ s{ (?=\pL)(\S)     (\S*) }
              { ucfirst($1) . lc($2)  }xge;
     return $str;
 }

如您所见，使其在该特定程序中工作的关键是这行代码，它只调用上面定义的其他函数，并使用我正在讨论的模块：

print pad(entitle($item), $width, ".");

这将使用点作为填充字符将项目填充到给定的宽度。

是的，它不那么方便printf，但至少是可能的。

于 2012-05-26T07:37:53.450 回答