7

我有一个单子变压器堆栈，包括一个ErrorT，我想ContT r在整个东西周围包裹一个变压器。当我尝试这样做时，我对throwError生成类型错误的调用 - 显然ContT r不会自动成为MonadError. 好吧，我想——我就把它变成一个：

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError = liftCatch . catchError

使用一些合适的定义liftCatch。但是现在编译时出现错误：

src\Language\Types.hs:68:10:
    Illegal instance declaration for `MonadError e (ContT r m)'
      (the Coverage Condition fails for one of the functional dependencies;
       Use -XUndecidableInstances to permit this)
    In the instance declaration for `MonadError e (ContT r m)'

我很高兴使用 UndecidableInstances 杂注（我的印象不是太令人担忧，例如看到这个问题）但我想知道将延续转换器变成一个实例是否有困难MonadError- 我想如果它是好吧，这个包的作者Control.Monad.Trans早就做了……对吧？

4

1 回答 1

9

ContT 和 ErrorT 都允许非标准控制流。有一种方法可以在 mtl 中将 ErrorT 类型包装在 ContT 周围：

instance (Error e, MonadCont m) => MonadCont (ErrorT e m)

但是这两个单子变压器不通勤。记住：

newtype Identity a = Identity {runIdentity :: a}
newtype ErrorT e m a = ErrorT {runErrorT :: m (Either e a)}
newtype ContT r m a = ContT {runContT :: (a -> m r) -> m r}

ErrorT String (ContT Bool Identity) ()在 mtl 包中没问题的可能是：

ErrorT (ContT ( \ (k :: Either String () -> Identity Bool) -> k (Right ()) ) )

ContT r (ErrorT e Identity) a在 mtl 包中不行。但是你可以写。

您想要在组合单子中的 (>>=) 语义是什么？您希望您的嵌套错误处理程序堆栈如何与非本地 callCC 交互？

以下是我的写法：

{-# LANGUAGE FlexibleInstances, MultiParamTypeClasses, UndecidableInstances   #-}
import Control.Monad
import Control.Monad.Cont
import Control.Monad.Error
import Data.Function
import Data.IORef

handleError :: MonadError e m => (e -> m a) -> m a -> m a
handleError = flip catchError

test2 :: ErrorT String (ContT () IO) ()
test2 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go2 = runContT (runErrorT test2) (either error return)

{-

*Main> go2
1
2
3
4
*** Exception: ouch:middle:top

-}

所以上面只适用于 mtl，这是新实例及其工作原理：

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError op h = ContT $ \k -> catchError (runContT op k) (\e -> runContT (h e) k)

test3 :: ContT () (ErrorT String IO) ()
test3 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go3 = runErrorT (runContT test3 return)

{-

*Main> go3
1
2
3
4
Left "ouch:middle:3:middle:2:middle:1:middle:top"

-}
于 2012-05-24T18:00:19.607 回答