actionscript-3 - AS3 - 缩放位图数据

Question

我想将 BitmapData 缩放到不同的大小，例如 200、400、600 和 800。

有什么好的方法可以做到这一点？

Answer 1

您不能直接缩放 a BitmapData，但可以对其进行缩放克隆。这是缩放 a 的简单示例BitmapData：

package {
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.geom.Matrix;

import mx.core.BitmapAsset;

public class Test extends Sprite {


    [Embed(source="test.jpg")]
    private var Image:Class;

    public function Test() {

        var originalBitmapData:BitmapData = BitmapAsset(new Image()).bitmapData;

        function scaleBitmapData(bitmapData:BitmapData, scale:Number):BitmapData {
            scale = Math.abs(scale);
            var width:int = (bitmapData.width * scale) || 1;
            var height:int = (bitmapData.height * scale) || 1;
            var transparent:Boolean = bitmapData.transparent;
            var result:BitmapData = new BitmapData(width, height, transparent);
            var matrix:Matrix = new Matrix();
            matrix.scale(scale, scale);
            result.draw(bitmapData, matrix);
            return result;
        }

        var bitmapA:Bitmap = new Bitmap(originalBitmapData);
        addChild(bitmapA);

        var bitmapB:Bitmap = new Bitmap(scaleBitmapData(originalBitmapData, 0.5));
        addChild(bitmapB);

    }
}
}

Answer 2

设置位图对象的宽度和高度会缩放该图像，因此使用您的 bitmapData 创建一个位图，然后使用宽度/高度对其进行缩放，或者如果您想使用缩放值，请使用 scaleX/Y。

var bmp:Bitmap = new Bitmap(bmpData);
bmp.width = 400; //  or 600,800 etc.
bmp.height = 400;

如果您不想使用位图对象并直接缩放 BitmapData，请参阅此 调整 BitmapData 对象大小的最佳方法是什么？