5

我有一个 xml 文档，如下所示：

<p>
  <c1 />
  <c2 />
</p>

子元素 c1 和 c2 是可选的，但对于处理步骤，我需要它们存在。所以我正在尝试创建一个 xslt 样式表以将它们添加为空元素（子元素的顺序无关紧要）。

这是我的样式表：

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="p[not(c1)]">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
        <c1 />
    </xsl:copy>
</xsl:template>

<xsl:template match="p[not(c2)]">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
        <c2 />
    </xsl:copy>
</xsl:template>

只要只缺少一个子元素，这就可以正常工作。但如果两者都缺失，则仅创建 c1。我如何防止这种情况并强制创建 c1 和 c2 （实际上是大约 10 个孩子）？

谢谢。约斯特

4

3 回答 3

4

不太喜欢这种xsl:if方法。只要您不介意更改节点的顺序，这可能会更好：

<!--generic copy rule-->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates" select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!--copy rules specific to p-->
<xsl:template match="p">
    <xsl:copy>
        <xsl:apply-templates select="not(self::c1|self::c2)"/>
        <c1><xsl:apply-templates select="c1/*"/></c1>
        <c2><xsl:apply-templates select="c2/*"/></c2>
    </xsl:copy>
<xsl:template>

基本思想是显式地生成 c1 和 c2 节点及其内容（如果存在，则不存在）。

于 2012-05-23T01:46:36.673 回答
2

我会这样做：

<xsl:template match="p"> 
  <xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
    <xsl:if test="not(c1)">
      <c1 /> 
    </xsl:if>
    <xsl:if test="not(c2)">
      <c2 /> 
    </xsl:if>
  </xsl:copy> 
</xsl:template>

如果您有更长的可能子节点列表，则可以将它们放在变量中并使用 afor-each而不是 individual if：

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
  exclude-result-prefixes="msxsl">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:variable name="childrenFragment">
    <c1/>
    <c2/>
  </xsl:variable>

  <xsl:template match="p">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
      <xsl:variable name="this" select="."/>
      <xsl:for-each select="msxsl:node-set($childrenFragment)/*">
        <xsl:variable name="localName" select="local-name()"/>
        <xsl:if test="not($this/*[local-name()=$localName])">
          <xsl:element name="{$localName}"/>
        </xsl:if>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

只需在childrenFragment变量中添加您需要的所有元素。

（这些msxsl:node-set东西是微软特有的，如果你使用的是另一个 XSLT 处理器，你需要一些稍微不同的东西）

于 2012-05-22T23:26:16.833 回答
2

xsl:element这是一个不使用任何显式 XSLT 条件指令或任何指令的通用 XSLT 1.0 解决方案（可与 N 个待添加元素一起使用）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vrtfNodesToAdd">
  <c1/><c2/>
</xsl:variable>

 <xsl:variable name="vNodesToAdd" select=
  "ext:node-set($vrtfNodesToAdd)/*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="p">
   <xsl:variable name="vCurrentP" select="."/>

   <xsl:copy>
    <xsl:apply-templates/>

    <xsl:for-each select="$vNodesToAdd">
       <xsl:copy-of select=
       "self::node()[not($vCurrentP/*[name() = name(current())])]"/>
    </xsl:for-each>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
 <p>
 </p>
 <p>
  <c1/>
 </p>
 <p>
  <c2/>
 </p>
 <p>
  <c1/><c2/>
 </p>
</t>

产生了想要的正确结果：

<t>
  <p>
    <c1 />
    <c2 />
  </p>
  <p>
    <c1 />
    <c2 />
  </p>
  <p>
    <c2 />
    <c1 />
  </p>
  <p>
    <c1 />
    <c2 />
  </p>
</t>
于 2012-05-23T03:56:35.877 回答