6

问题一：

我想将数组传递给函数。但是传递的参数在函数中发生了变化。它是按值调用的吗？

问题2：

#my ($name, $num, @array)= @_;   <=1 )
my $name = shift;                <=2 )
my $num = shift;
my @array = shift;

情况 1 和 2 的输出不同。为什么会发生？

#!/usr/bin/perl
use strict;

my @test1;
push @test1, ['a', 1];
push @test1, ['b', 1];
push @test1, ['c', 1];
push @test1, ['d', 1];
push @test1, ['e', 1];

for (my $i=0; $i< scalar(@test1); $i++) {
    print "out1: $test1[$i][0]  $test1[$i][1]\n";
}

test_func("test_func", 10, @test1);

sub test_func {
    #my ($name, $num, @array)= @_;   <=1)
    my $name = shift;                <=2)
    my $num = shift;
    my @array = shift;

    print "$name\n";
    print "$num\n";

    for (my $i=0; $i< scalar(@test1); $i++) {
        print "$array[$i][0]  $array[$i][1]\n";
    }

    for (my $i=0; $i< scalar(@test1); $i++) {
        if ($array[$i][0] eq 'a') {
            $array[$i][0] = 'z';
        }
    }
    for (my $i=0; $i< scalar(@test1); $i++) {
        print "change: $array[$i][0]  $array[$i][1]\n";
    }
}

for (my $i=0; $i< scalar(@test1); $i++) {
    print "out2: $test1[$i][0]  $test1[$i][1]\n";
}
#

下面是测试输出。

out1: a  1
out1: b  1
out1: c  1
out1: d  1
out1: e  1
test_func
10
a  1
b  1
c  1
d  1
e  1
change: z  1
change: b  1
change: c  1
change: d  1
change: e  1
out2: z  1 <= Why did it change?
out2: b  1
out2: c  1
out2: d  1
out2: e  1
4

1 回答 1

11
我想将一个数组传递给一个函数 [...] 有不同的输出。为什么会发生？

您不能将数组传递给函数sub。Subs 只能将标量列表作为参数。

test_func("test_func", 10, @test1);

是相同的

test_func("test_func", 10, $test1[0], $test1[1], $test1[2], $test1[3], $test1[4]);

test_func当你这样做时，你正在创建一个新数组

my ($name, $num, @array) = @_;

shift返回 的第一个元素@_，它必然是一个标量。@_是一个数组，数组的元素是标量。等价的将是

my $name  = shift(@_);
my $num   = shift(@_);
my @array = splice(@_);

要将数组传递给子，通常会传递对它的引用。

test_func("test_func", 10, \@test1);

my ($name, $num, $array) = @_;

my $name  = shift;
my $num   = shift;
my $array = shift;

say "@$array";
但是传递的参数在函数中发生了变化。它是按值调用的吗？

Perl 从不按值传递。它总是通过引用传递。如果您更改 的任何元素@_，它将更改调用者中的相应参数。

$ perl -E'sub f { $_[0] = "def"; }  my $x = "abc"; f($x); say $x;'
def

但这不是问题。您不会更改@_. 您正在做的是更改$test[0]和引用的单个数组$array[0]。

这就是你正在做的事情：

my $ref1 = [ 'a', 1 ];  # aka $test1[0]
my $ref2 = $ref1;       # aka $array[0]
$ref2->[0] = 'z';       # Changes the single array (not $ref1 or $ref2).

它的简称

my @anon = ( 'a', 1 );
my $ref1 = \@anon;      # aka $test1[0]
my $ref2 = $ref1;       # aka $array[0]
$ref2->[0] = 'z';       # Changes @anon (not $ref1 or $ref2).

Storabledclone可用于制作数组的“深拷贝” 。

my $ref1 = [ 'a', 1 ];
my $ref2 = dclone($ref1);  # clones the reference, the array, 'a' and 1.
$ref1->[0] = 'y';          # Changes the original array
$ref2->[0] = 'z';          # Changes the new array
于 2012-05-22T16:25:04.970 回答