5

我有一些 OpenGL 的示例源代码，我想编译一个 64 位版本（使用 Delphi XE2）但是有一些 ASM 代码无法编译，我对 ASM 一无所知。这是下面的代码，我将两条错误消息放在失败的行上......

// Copy a pixel from source to dest and Swap the RGB color values
procedure CopySwapPixel(const Source, Destination: Pointer);
asm
  push ebx //[DCC Error]: E2116 Invalid combination of opcode and operands
  mov bl,[eax+0]
  mov bh,[eax+1]
  mov [edx+2],bl
  mov [edx+1],bh
  mov bl,[eax+2]
  mov bh,[eax+3]
  mov [edx+0],bl
  mov [edx+3],bh
  pop ebx //[DCC Error]: E2116 Invalid combination of opcode and operands
end;
4

2 回答 2

13

此过程将 ABGR 字节顺序交换为 ARGB，反之亦然。
在 32 位中，这段代码应该完成所有工作：

mov ecx, [eax]  //ABGR from src
bswap ecx       //RGBA  
ror ecx, 8      //ARGB 
mov [edx], ecx  //to dest

X64 的正确代码是

mov ecx, [rcx]  //ABGR from src
bswap ecx       //RGBA  
ror ecx, 8      //ARGB 
mov [rdx], ecx  //to dest

另一个选项 - 制作纯 Pascal 版本，它更改数组表示中的字节顺序：0123 到 2103（交换第 0 和第 2 个字节）。

procedure Swp(const Source, Destination: Pointer);
var
  s, d: PByteArray;
begin
  s := PByteArray(Source);
  d := PByteArray(Destination);
  d[0] := s[2];
  d[1] := s[1];
  d[2] := s[0];
  d[3] := s[3];
end;
于 2012-05-22T04:56:19.923 回答
3

64位有不同的指针寄存器名称，传递差异。内联汇编函数的前四个参数分别通过 RCX、RDX、R8 和 R9 传递

EBX -> RBX
EAX -> RAX
EDX -> RDX

试试这个

procedure CopySwapPixel(const Source, Destination: Pointer);
{$IFDEF CPUX64}
asm
  mov al,[rcx+0]
  mov ah,[rcx+1]
  mov [rdx+2],al
  mov [rdx+1],ah
  mov al,[rcx+2]
  mov ah,[rcx+3]
  mov [rdx+0],al
  mov [rdx+3],ah
end;
{$ELSE}
asm
  push ebx //[DCC Error]: E2116 Invalid combination of opcode and operands
  mov bl,[eax+0]
  mov bh,[eax+1]
  mov [edx+2],bl
  mov [edx+1],bh
  mov bl,[eax+2]
  mov bh,[eax+3]
  mov [edx+0],bl
  mov [edx+3],bh
  pop ebx //[DCC Error]: E2116 Invalid combination of opcode and operands
end;
{$ENDIF}
于 2012-05-22T14:37:53.050 回答