1

我需要从位于我的 xml 源中不同节点的数字构造一个字符串，但需要注意的是数据速率节点顺序将是随机的，并且起始数字必须以至少 600 开头。如果没有 600，则开始800。

<datarate rate="200" />
<datarate rate="600" />
<datarate rate="300" />
<datarate rate="400" />
<datarate rate="800" />
<datarate rate="1000" />

http://example.com/src/600/800/

我尝试过根据组进行排序，但无济于事。有人有想法吗？

感谢您的任何帮助，您可以提供！

4

3 回答 3

1

使用 XSLT 2，您可以这样做：

<xsl:template match="/">
   <xsl:for-each select="//datarate[number(@rate) ge 600]">
      <xsl:sort select="@rate" data-type="number"/>
      <xsl:value-of select="@rate"/>
      <xsl:if test="not(position() eq last())">
         <xsl:text>, </xsl:text>
      </xsl:if>
   </xsl:for-each>
</xsl:template>
于 2012-05-21T17:19:37.047 回答
0

如果您预先知道阈值，您可以像这样进行非常简单的转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" encoding="UTF-8"/>

    <xsl:template match="/">
        <xsl:apply-templates select="//datarate">
            <xsl:sort select="@rate" data-type="number"/>
        </xsl:apply-templates>
    </xsl:template> 

    <xsl:template match="datarate[@rate &lt; 600]"/>

    <xsl:template match="datarate">
        [<xsl:value-of select="@rate"/>]
    </xsl:template>
</xsl:stylesheet>

由于您需要检查是否存在 a600并800在未找到时用作阈值600，因此您可以这样：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text" encoding="UTF-8"/>

   <xsl:variable name="threshold">
       <xsl:choose>
           <xsl:when test="//datarate[@rate = 600]">600</xsl:when>
           <xsl:otherwise>800</xsl:otherwise>
       </xsl:choose>
   </xsl:variable>

   <xsl:template match="/">
       <xsl:apply-templates select="//datarate">
           <xsl:sort select="@rate" data-type="number"/>
       </xsl:apply-templates>
   </xsl:template>  

   <xsl:template match="datarate[@rate &lt; $threshold]"/>

   <xsl:template match="datarate">
       [<xsl:value-of select="@rate"/>]
   </xsl:template>
</xsl:stylesheet>

如果可能既没有 a600也没有 a，800您可能希望在$threshold变量声明中添加更多逻辑。

ps 没有关于您希望如何构造字符串的详细信息，我只是打印了@rate包含在[].

于 2012-05-21T16:04:21.360 回答
0

这个简短而简单的转换（根本没有使用明确的条件指令—— no xsl:choose, no xsl:when, no xsl:otherwise）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*">
  <t>
    <xsl:apply-templates select="*">
     <xsl:sort select="@rate" data-type="number"/>
    </xsl:apply-templates>
  </t>
 </xsl:template>

 <xsl:template match=
  "datarate
     [not(@rate >= 600)
     or
      not(../*[@rate = 600]) and not(@rate >= 800)
     ]"/>
</xsl:stylesheet>

当应用于提供的 XML 文档时（包装到单个顶部元素中以形成良好的格式）：

<t>
    <datarate rate="200" />
    <datarate rate="600" />
    <datarate rate="300" />
    <datarate rate="400" />
    <datarate rate="800" />
    <datarate rate="1000" />
</t>

产生想要的正确结果：

<t>
   <datarate rate="600"/>
   <datarate rate="800"/>
   <datarate rate="1000"/>
</t>

当应用于以下稍有变化的 XML 文档时（没有 600 的比率，但有 601 和 650 的比率）：

<t>
    <datarate rate="200" />
    <datarate rate="601" />
    <datarate rate="650" />
    <datarate rate="300" />
    <datarate rate="400" />
    <datarate rate="800" />
    <datarate rate="1000" />
</t>

再次产生正确的结果：

<t>
   <datarate rate="800"/>
   <datarate rate="1000"/>
</t>
于 2012-05-22T02:30:48.527 回答