当您使用非英语（俄语）键盘布局时，是否有一种简单的方法来使用 Emacs 键绑定？
每当打开国际布局时，所有击键都按字面意思解释，M-ф 而不是 Ma。结果我不能使用命令。
如果 Linux 可以根据国际布局解释无前缀和带移位前缀的键，同时保留其余的英文，那也很好。
问问题
4841 次
5 回答
13
您可以通过键入设置输入法（荣誉转到kindahero）
M-x set-input-method RET cyrillic-yawerty RET
或者
M-x set-input-method RET cyrillic-jcuken RET
要永久存储它，请添加
(setq default-input-method "cyrillic-yawerty")
到~/.emacs配置（并用于C-\在键盘布局之间切换）。
于 2012-05-17T17:57:02.283 回答
7
这是基于 syndikat 回答的使用操作系统语言的替代解决方案。
缺少一些关键的翻译，但应该很容易添加它们。
;; USAGE:
;; Put in your .emacs:
;;
;; (translate-keystrokes-ru->en)
;; (add-hook 'text-mode-hook
;; (lambda () (literal-insert-mode 1)))
;;
;; Only buffers with literal-insert-mode active will be sensitive to the
;; environment language. Prefixed keybindings will still be usable.
(defun translate-keystrokes-ru->en ()
"Make emacs output english characters, regardless whether
the OS keyboard is english or russian"
(flet ((make-key-stroke (prefix char)
(eval `(kbd ,(if (and (string-match "^C-" prefix)
(string-match "[A-Z]" (string char)))
(concat "S-" prefix (string (downcase char)))
(concat prefix (string char)))))))
(let ((case-fold-search nil)
(keys-pairs (mapcar* 'cons
"йцукенгшщзхъфывапролджэячсмитьбюЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖ\ЭЯЧСМИТЬБЮ№"
"qwertyuiop[]asdfghjkl;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>#"))
(prefixes '("" "s-" "M-" "M-s-"
"C-" "C-s-" "C-M-" "C-M-s-")))
(mapc (lambda (prefix)
(mapc (lambda (pair)
(define-key key-translation-map
(make-key-stroke prefix (car pair))
(make-key-stroke prefix (cdr pair))))
keys-pairs))
prefixes))))
(defun literal-insert ()
(interactive)
(insert-char last-input-event 1))
(define-minor-mode literal-insert-mode
"Make emacs output characters corresponging to the OS keyboard,
ignoring the key-translation-map"
:keymap (let ((new-map (make-sparse-keymap))
(english-chars "qwertyuiop[]asdfghjkl;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>#"))
(mapc (lambda (char)
(define-key new-map (string char)
'literal-insert))
english-chars)
new-map))
于 2012-06-05T02:18:20.563 回答
3
不确定，sabof 哪来的 1500 亿。我运行了这段代码（感谢 Yuri Khan，取自EmacsWiki）：
(loop
for from across "йцукенгшщзхъфывапролджэячсмитьбюЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖ\ЭЯЧСМИТЬБЮ№"
for to across "qwertyuiop[]asdfghjkl;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>#"
do
(eval `(define-key key-translation-map (kbd ,(concat "C-" (string from))) (kbd ,(concat "C-" (string to)))))
(eval `(define-key key-translation-map (kbd ,(concat "M-" (string from))) (kbd ,(concat "M-" (string to))))))
它只有 128 种组合。不幸的是，像单个字母这样的组合C-x b不起作用。我仍在努力寻找更好的解决方案。
于 2012-06-03T17:42:48.957 回答
1
我对西里尔文键盘使用以下代码段，它对我来说很好用：
(defun reverse-input-method (input-method)
"Build the reverse mapping of single letters from INPUT-METHOD."
(interactive
(list (read-input-method-name "Use input method (default current): ")))
(if (and input-method (symbolp input-method))
(setq input-method (symbol-name input-method)))
(let ((current current-input-method)
(modifiers '(nil (control) (meta) (control meta))))
(when input-method
(activate-input-method input-method))
(when (and current-input-method quail-keyboard-layout)
(dolist (map (cdr (quail-map)))
(let* ((to (car map))
(from (quail-get-translation
(cadr map) (char-to-string to) 1)))
(when (and (characterp from) (characterp to))
(dolist (mod modifiers)
(define-key local-function-key-map
(vector (append mod (list from)))
(vector (append mod (list to)))))))))
(when input-method
(activate-input-method current))))
(reverse-input-method 'russian-computer)
除了：
我知道的唯一问题是 OrgTable 公式的重新计算在俄语布局中不起作用，因为它被映射到 Cc-* 并且 * 更改了它的位置。
于 2019-02-12T10:05:47.817 回答
0
如果您想在 Emacs 中继续使用俄语布局（而不是使用 Emacs 自己的输入法），我现在知道的唯一方法是添加表单的绑定：
(define-key function-key-map [?\M-ф] [?\M-a])
这将告诉 Emacs，如果 M-ф 没有绑定，它应该尝试查找 Ma。可悲的是，您将需要很多这样的绑定。如果有人编写了一个可以自动提供所有这些绑定的补丁/包，我很乐意将它包含在 Emacs 中。
于 2012-05-18T19:32:42.247 回答