2

我有一个样式表，用于根据其他元素的值删除某些元素。但是，它不起作用...

示例输入 XML

<Model>
<Year>1999</Year>
<Operation>ABC</Operation>
<Text>Testing</Text>
<Status>Ok</Status>
</Model>

如果 Operation 值为“ABC”，则从 XML 中删除 Text 和 Status 节点。并给出以下输出。

<Model>
<Year>1999</Year>
<Operation>ABC</Operation>
</Model>

这是我正在使用的样式表，但即使操作不是“ABC”，它也会从所有 XML 中删除文本和状态节点。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>
  <xsl:variable name="ID" select="//Operation"/>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="Text | Status">
    <xsl:if test ="$ID ='ABC'">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

提前致谢

当命名空间存在时我将如何做同样的事情

<ns0:next type="Sale" xmlns:ns0="http://Test.Schemas.Inside_Sales">
4

4 回答 4

5

这是一个完整的 XSLT 转换——简短而简单（没有变量，没有xsl:if, xsl:choose, xsl:when, xsl:otherwise）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match=
 "*[Operation='ABC']/Text | *[Operation='ABC']/Status"/>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Model>
    <Year>1999</Year>
    <Operation>ABC</Operation>
    <Text>Testing</Text>
    <Status>Ok</Status>
</Model>

产生了想要的正确结果：

<Model>
   <Year>1999</Year>
   <Operation>ABC</Operation>
</Model>
于 2012-05-17T04:24:29.717 回答
4

更改xsl:if如下：

<xsl:if test="../Operation!='ABC'">

你可以摆脱xsl:variable.

于 2012-05-17T00:26:15.980 回答
3

XSLT 中比使用更好的模式<xsl:if>是添加具有匹配条件的新模板：

<xsl:template match="(Text | Status)[../Operation != 'ABC']"/>
于 2012-05-17T03:42:00.660 回答
2

我发现这有效：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="/Model">
      <xsl:choose>
        <xsl:when test="Operation[text()!='ABC']">
            <xsl:copy>
                <xsl:apply-templates select="node()|@*"/>
            </xsl:copy>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy>
                <xsl:apply-templates select="Year"/>
                <xsl:apply-templates select="Operation"/>
            </xsl:copy>
        </xsl:otherwise>
      </xsl:choose>
  </xsl:template>
</xsl:stylesheet>
于 2012-05-17T00:31:53.133 回答