0

我已经尝试了所有我看到的将一个月添加到某个日期然后以特定格式返回的方法，但我不知所措。这是我的代码，但我需要对其进行格式化：

replace( formatdatetime( dateadd( "m" , 1 , request("date") ), 0 ) , "/" , "-" ) & "' )

request("date")是yyyyy-dd-mm hh:mm:ss格式，这就是我需要新日期的方式。

4

3 回答 3

1

这可能会有所帮助：

FormatDateTime(DateAdd("M",1,DateSerial(Left(request("date"),4),Mid(request("date"),9,2),Mid(request("date"),6,2))) & " " & Mid(request("date"),12,8),d,0)

它基本上将字符串转换为本机格式的有效日期，添加 1 个请求的月份，然后重建字符串。

注意： request("date") 看起来好像它返回当前日期时间，因此以这种方式运行它可能会生成一个大约一秒的最终值，如果这是一个问题，那么您最好将静态值存储在变量，否则这应该没问题。

于 2012-05-16T10:48:28.003 回答
1

以下应该可以完美运行：

replace( formatdatetime( dateadd( "m" , 1 , cDate(request("date")) ), 0 ) , "/" , "-" )

请注意使用该cDate函数将值显式转换为日期。

编辑：

我删除了你代码的最后一部分，& "' )否则它给了我一个错误。

于 2012-05-16T10:20:59.253 回答
1

处理日期时，特别重要的是要注意正确的数据（子）类型。将字符串提供给需要日期的函数（并依赖“VBScript - 和您的本地设置 - 将做正确的事情”）是危险的。

使用替换永远不会改变日期部分的顺序。

FormatDateTime 取决于本地/区域设置，应避免将其作为灾难的可靠途径。

解决此问题的一种方法 + 与 VBScript 中精美格式相关的大多数其他问题是使用 .Net System.Text.StringBuilder：

给定 Lib.vbs：

' Lib.vbs - simple VBScript library/module
' use
'  ExecuteGlobal goFS.OpenTextFile(<PathTo\Lib.vbs>).ReadAll()
' to 'include' Lib.vbs in you main script

Class ToBeAShamedOf
  Public a
  Public b
End Class ' ToBeAShamedOf

Class cFormat
  Private m_oSB
  Private Sub Class_Initialize()
    Set m_oSB = CreateObject("System.Text.StringBuilder")
  End Sub ' Class_Initialize
  Public Function formatOne(sFmt, vElm)
    m_oSB.AppendFormat sFmt, vElm
    formatOne = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatOne
  Public Function formatArray(sFmt, aElms)
    m_oSB.AppendFormat_4 sFmt, (aElms)
    formatArray = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatArray
End Class ' cFormat

和 main.vbs：

' main.vbs - demo use of library/module Lib.vbs

' Globals
Dim gsLibDir : gsLibDir = ".\"
Dim goFS     : Set goFS = CreateObject("Scripting.FileSystemObject")

' LibraryInclude
ExecuteGlobal goFS.OpenTextFile(goFS.BuildPath(gsLibDir, "Lib.vbs")).ReadAll()

WScript.Quit demoDateFormat()
WScript.Quit main()

Function main()
  Dim o : Set o = New ToBeAShamedOf
  o.a = 4711
  o.b = "whatever"
  WScript.Echo o.a, o.b
  main = 1 ' can't call this a success
End Function ' main

Function demoDateFormat()
  Dim sD   : sD       = "2012-05-16 01:02:03" ' near future; not yyyyy!
  Dim dtD  : dtD      = CDate(sD)
  Dim dtDM : dtDM     = DateAdd("m", 1, dtD)
  Dim oFmt : Set oFmt = New cFormat
  WScript.Echo oFmt.formatArray( _
      "   sD: {1}{0}  dtD: {2}{0} dtDM: {3}{0}dtDM': {4}" _
    , Array(vbCrLf, sD, dtD, dtDM, oFmt.formatOne("{0:yyyy-MM-dd hh:mm:ss}", dtDM)))
  demoDateFormat = 0 ' seems to be decent
End Function ' demoDateFormat

你会得到：

cscript main.vbs
   sD: 2012-05-16 01:02:03
  dtD: 16.05.2012 01:02:03
 dtDM: 16.06.2012 01:02:03
dtDM': 2012-06-16 01:02:03

（要在这个答案的上下文中看到）

于 2012-05-16T10:28:48.127 回答