vbscript - 从另一个 .VBS 文件创建一个类的实例（位于 B.vbs 中）

Question

我有 2 个 vbs 文件。

A.vbs：

Class test
  public a
  public b
End Class

B.vbs：

Dim objShell
Set objShell = Wscript.CreateObject("WScript.Shell")
objShell.Run "C:\Users\shanmugavel.chinnago\Desktop\Test3.vbs" 

Dim ins
Set ins = new test 'Here throws "Class not defined: test"
ins.a = 10
ins.b = "SCS"

msgbox ins.a
msgbox ins.b

现在我想在 B.vbs 文件中实现这一点。但是在为 A.vbs 中可用的类创建实例时会引发错误。有什么帮助吗？

Answer 1

. 运行.vbs 不会使代码在另一个中可用。一个简单但可扩展的策略是在“库”上使用 .ExecuteGlobal。给定

库.vbs：

' Lib.vbs - simple VBScript library/module
' use
'  ExecuteGlobal goFS.OpenTextFile(<PathTo\Lib.vbs>).ReadAll()
' to 'include' Lib.vbs in you main script

Class ToBeAShamedOf
  Public a
  Public b
End Class ' ToBeAShamedOf

和 main.vbs：

' main.vbs - demo use of library/module Lib.vbs

' Globals
Dim gsLibDir : gsLibDir = ".\"
Dim goFS     : Set goFS = CreateObject("Scripting.FileSystemObject")

' LibraryInclude
ExecuteGlobal goFS.OpenTextFile(goFS.BuildPath(gsLibDir, "Lib.vbs")).ReadAll()

WScript.Quit main()

Function main()
  Dim o : Set o = New ToBeAShamedOf
  o.a = 4711
  o.b = "whatever"
  WScript.Echo o.a, o.b
  main = 1 ' can't call this a success
End Function ' main

你会得到：

cscript main.vbs
4711 whatever

（参见this answer以获得有用类的种子）

Answer 2

您的 b 脚本与您的 a 脚本没有联系，您需要像这样包含代码，然后您可以使用来自 a 的代码，就像它存在于 b 中一样

call Include("a.vbs")

Sub Include (Scriptnaam)
  Dim oFile
  Set oFile = oFso.OpenTextFile(Scriptnaam)
  ExecuteGlobal oFile.ReadAll()
  oFile.Close
End Sub

Answer 3

您可以将 B.vbs 转换为允许您包含 A.vbs的Windows 脚本文件。

Answer 4

这是我们用来执行此操作的代码。

Sub Include(sInstFile)
    Dim f, s, oFSO
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    On Error Resume Next
    If oFSO.FileExists(sInstFile) Then
        Set f = oFSO.OpenTextFile(sInstFile)
        s = f.ReadAll
        f.Close
        ExecuteGlobal s
    End If
    On Error Goto 0
    Set f = Nothing
    Set oFSO = Nothing
End Sub

Include("c:\files\SSDConnection.vbs")
Include("c:\files\SSDTable.vbs")

对我们的团队完美无瑕