3

我试图弄清楚如何生成一个集合列表，其中每个集合的长度为 N，每个集合的总和为 X。

我找到了这段代码：

num_split(0,[]).
num_split(N, [X | List]):-
   between(1,N,X),
   plus(X,Y,N),
   num_split(Y,List).

我可以使用它来获取总和 X 的集合列表：

num_split(6,List),length(List,5).
List = [1, 1, 1, 1, 2] ;
List = [1, 1, 1, 2, 1] ;
List = [1, 1, 2, 1, 1] ;
List = [1, 2, 1, 1, 1] ;
List = [2, 1, 1, 1, 1] ;
false.

问题是这些都是排列，我正在寻找组合。我正在寻找的输出应该是这样的get_combos(Sum,Length,List)：

get_combos(6,2,List).
List = [5,1];
List = [4,2];
List = [3,3];
false.

任何指针？

4

2 回答 2

3

如果您有权访问CLP(FD)库，则可以使用以下代码：

:- [library(clpfd)].

get_combos(Sum, Length, List) :-
    length(List, Length),
    List ins 1 .. Sum,
%   all_distinct(List), not really useful here
    sum(List, #=, Sum),
    chain(List, #<),
    label(List).

测试：

?- get_combos(10,3,L).
L = [1, 2, 7] ;
L = [1, 3, 6] ;
L = [1, 4, 5] ;
L = [2, 3, 5] ;

也许我误解了你的问题。使用这个链

...
chain(List, #=<),
....

获取可能的重复值：

?- get_combos(10,3,L).
L = [1, 1, 8] ;
L = [1, 2, 7] ;
L = [1, 3, 6] ;
L = [1, 4, 5] ;
L = [2, 2, 6] ;
L = [2, 3, 5] ;
L = [2, 4, 4] ;
L = [3, 3, 4] ;
false.
于 2012-05-16T07:04:58.523 回答
1

在数组中的连续值之间强制执行“相等或更大”的限制。

您可以将其添加为另一个谓词：

is_combination([]).
is_combination([_]).
is_combination([A,B|List]) :- A =< B, is_combination([B|List]).

get_combos(Sum, Length, List) :-
    num_split(Sum, Length, List),
    is_combination(List).

不幸的是，在 num_split/3 末尾添加它并不一定会提高其性能，因此将其直接添加到算法中会稍微好一点：

get_combos(_, 0, []).
get_combos(Sum, 1, [Sum]).
get_combos(Sum, Length, [A, B|List]) :-
    between(1, Sum, A),
    plus(A, NextSum, Sum),
    plus(1, NextLength, Length),
    get_combos(NextSum, NextLength, [B|List]),
    A =< B.

我不确定这可以获得多少性能，因为比较必须在递归之后进行，因为小于或等于运算符 (=<) 需要完全实例化两个操作数才能使其工作。

于 2012-05-16T03:41:55.143 回答