1

我有一个看起来像这样的源 XML

<parent>
      <child id="123456">Child Name
      </child>
      <image name="child.jpg">
</parent>

目标 XML 应该是

<data>
     <person id="123456">
        <name>Child Name</name>
     </person>
     <relation id="123456">
        <filename>child.jpg</filename>
     </relation>
</data>

我正在使用 XSLT 来转换它。问题是，我什么时候可以使用 XSLT 从目标 XML 中两个不同位置的源 XML 中获取 id 的值（即 123456）。

4

2 回答 2

2

这是一个简短而简单的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="parent">
     <data>
       <xsl:apply-templates/>
     </data>
 </xsl:template>

 <xsl:template match="child">
  <person id="{@id}">
    <name><xsl:value-of select="."/></name>
  </person>
 </xsl:template>

 <xsl:template match="image">
  <relation id="{preceding-sibling::child[1]/@id}">
   <filename><xsl:value-of select="@name"/></filename>
  </relation>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<parent>
    <child id="123456">Child Name</child>
    <image name="child.jpg"/>
</parent>

产生了想要的正确结果：

<data>
   <person id="123456">
      <name>Child Name</name>
   </person>
   <relation id="123456">
      <filename>child.jpg</filename>
   </relation>
</data>
于 2012-05-14T13:14:52.083 回答
0

你可以试试这个： XSL：

<?xml version='1.0'?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/">
    <data>
        <xsl:for-each select="parent">
            <!--variable to store @id-->
            <xsl:variable name="id" select="child/@id"/>
            <!--creating a test comment node()-->
            <xsl:comment>Child having id: <xsl:value-of select="child/@id"/></xsl:comment>
            <xsl:element name="person">
                <xsl:attribute name="id"><xsl:value-of select="$id"/></xsl:attribute>
                <xsl:element name="name">
                    <xsl:value-of select="./child/text()"/>
                </xsl:element>
            </xsl:element>
            <xsl:element name="relation">
                <xsl:attribute name="id">
                    <xsl:value-of select="$id"/>
                </xsl:attribute>
                <xsl:element name="filename">
                    <xsl:value-of select="./image/@name"/>
                </xsl:element>
            </xsl:element>
        </xsl:for-each>
    </data>
</xsl:template>

</xsl:stylesheet>

输入 XML（您的，但稍作修改以使其格式良好）

<?xml version="1.0"?>
<parent>
      <child id="123456">Child Name</child>
      <image name="child.jpg"/>
</parent>

结果

<?xml version='1.0' ?>
<data>
  <!--Child having id: 123456-->
  <person id="123456">
    <name>Child Name</name>
  </person>
  <relation id="123456">
    <filename>child.jpg</filename>
  </relation>
</data>
于 2012-05-14T11:07:14.020 回答