0

我继承了一个coldfusion8 站点，它使用了一些搜索功能。

我正在尝试将标准化的数据库查询存储到存储过程中。由于我是 Coldfusion 和 MySQL 的新手，我现在想知道我是否可以在 MySQL 中做到这一点：

<cfquery datasource="db" name="find_cats">
    SELECT wg.no, wg.type, wg.keywords, wg.lang
    FROM cats AS wg 
    <cfloop list="searchForm.cats_search_string" delimiters=", " item="tag">
      WHERE wg.keywords LIKE <cfqueryparam value='%#tag#%' cfsqltype='cf_sql_varchar'> AND
    </cfloop>
    wg.lang = <cfqueryparam value="#Session.lang#" cfsqltype="cf_sql_varchar">
</cfquery>
<cfset cond_cats = "AND (1=2">
    <cfoutput query="find_cats">
        <!--- check if found category belongs to either AAA or BBB classifcation --->
        <cfif wg.type is "AAA">
            <cfset cond_cats = cond_cats & " OR categoryID1 = #wg.no#">
        </cfif>
        <cfif wg.typ is "BBB">
            <cfset cond_cats = cond_cats & " OR categoryID2 = #wg.no#">
        </cfif>
    </cfoutput>
    <cfset cond_cats = cond_cats & ")">

搜索可以基于关键字或索引（AAA、BBB）。我仍在尝试了解发生了什么，但到目前为止，我认为如果用户输入如下字符串：

 string1, string2, string3 string4

第一部分循环遍历四个字符串（分隔符逗号和空格）并查询数据库以查找匹配的关键字。然后它创建一个新的cond_cats变量，在实际搜索发生时使用该变量。我猜它用匹配的类别替换了搜索字符串，但我不确定这里，因为结果将是

AND (1=2 OR category1 = 12345 OR category2 = 88888 )

附加到实际的搜索查询中。

我的问题：
MySQL 中有没有办法拆分用户输入的搜索字符串，所以我可以运行循环？第二部分应该是存储过程的输出参数，不是吗？如果这在每次搜索之前运行，它应该是一个存储过程还是应该继续使用数据库查询？

感谢您的意见！

4

2 回答 2

1

根据您的描述，我没有看到将它包装在存储过程/函数中的好处。数据库并未真正针对字符串操作进行优化。虽然循环是可能的，但等效的 sql 代码通常远没有那么优雅。另外，它可能需要使用动态 sql（或临时表来安全地执行此操作）。

cfloop但是，查看您的代码，我相信您可以通过使用单个IN (....)子句而不是构造一系列OR条件来完全消除第二个。（两者是等价的。）

只需修改第一个查询以仅检索所需类型的类别，即“AAA”和“BBB”。

<cfquery datasource="db" name="find_cats">
    SELECT  wg.no
    FROM    cats AS wg 
    WHERE   wg.lang = <cfqueryparam value="#Session.lang#" cfsqltype="cf_sql_varchar">
    AND     wg.type IN ('AAA', 'BBB')
    AND  ( 1 = 2
         <cfloop list="#searchForm.cats_search_string#" delimiters=", " item="tag">
              OR wg.keywords LIKE <cfqueryparam value='%#tag#%' cfsqltype="cf_sql_varchar"> 
          </cfloop>
       )
</cfquery>

然后使用ValueList将结果提供给您的第二个查询。您甚至可以将两个查询合并为一个。但这一切都取决于您的搜索查询的复杂性。

WHERE categoryID1 IN 
( 
    <cfqueryparam value="#valueList(find_cats.no)#" list="true" ... > 
)

编辑： 我认为你仍然可以使用 valueList。只需在第一个查询中添加一条CASE语句，将匹配的值分成两列：

SELECT  wg.no
        , CASE WHEN wg.type = 'AAA' THEN wg.no ELSE NULL END AS ID1Values
        , CASE WHEN wg.type = 'BBB' THEN wg.no ELSE NULL END AS ID2Values
...

然后生成每列中的值列表：

     <cfset firstList  = valueList(find_cats.ID1Values)>
     <cfset secondList = valueList(find_cats.ID2Values)>

最后在您的搜索查询中使用这些列表。

   WHERE 1 = 2

   <cfif listLen(firstList)>
         OR categoryID1 IN ( <cfqueryparam value="#firstList#" list="true" cfsqltype="cf_sql_integer"> )
   </cfif>

   <cfif listLen(secondList)>
         OR categoryID2 IN ( <cfqueryparam value="#secondList#" list="true" cfsqltype="cf_sql_integer"> )
   </cfif>
于 2012-05-15T04:19:32.393 回答
0

我认为你应该在 mysql 中尝试“全文”索引。

于 2012-05-14T11:57:39.627 回答