5

我正在尝试使用 vbs 调用我的 excel 宏。这是我的代码片段。 

Set objExcel = CreateObject("Excel.Application")
Set objWorkbook = objExcel.Workbooks.Open("C:\Folder\Test_PO.xls")
objExcel.Application.Visible = True
objExcel.Application.Run "C:\Folder\Test_PO.xls!Data_Analysis"
objExcel.ActiveWorkbook.Close
objExcel.Application.Quit
WScript.Echo "Finished."
WScript.Quit

现在这里的问题是我能够打开文件，但是宏在这里被禁用并显示给我'macro may not be present or may be disabled'。我确定我正在调用正确的宏名称，但是一旦打开文件，我已将宏配置为从中运行的加载项选项卡就会消失。如果我手动打开文件，这不会打开，我可以看到选项卡并从选项卡本身运行宏。有什么建议我可以克服这个问题并让宏运行吗？

4

2 回答 2

7

尝试这个

Dim objExcel, objWorkbook 

Set objExcel = CreateObject("Excel.Application")
Set objWorkbook = objExcel.Workbooks.Open("C:\Folder\Test_PO.xls")
objExcel.Visible = True
objExcel.Run "Data_Analysis"
objWorkbook.Close
objExcel.Quit

Set objWorkbook = Nothing
Set objExcel = Nothing

WScript.Echo "Finished."
WScript.Quit

编辑

如果宏在一个模块中，那么上面的内容会有所帮助。如果宏在工作表中说，Sheet1 然后替换该行

objExcel.Run "Data_Analysis"

和

objExcel.Run "sheet1.Data_Analysis"

跟进

试试这个代码。

Dim objExcel, objWorkbook, ad, FilePath

Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = True

For Each ad In objExcel.AddIns
    If ad.Name = "Converteam.xla" Then
        FilePath = ad.Path & "\Converteam.xla"
        Exit For
    End If
Next

objExcel.Workbooks.Open (FilePath)

Set objWorkbook = objExcel.Workbooks.Open("C:\Folder\Test_PO.xls")

objExcel.Run "Data_Analysis_Converteam"
objWorkbook.Close
objExcel.Quit

Set objWorkbook = Nothing
Set objExcel = Nothing

WScript.Echo "Finished."
WScript.Quit

解释：

使用时CreateObject，默认情况下不安装加载项。请看这个链接。

主题：在 Excel 中使用 CreateObject 命令时加载项不加载

链接： http: //support.microsoft.com/kb/213489/

您必须加载加载项，然后调用相关的宏。此外，您的宏的名称不是Data_Analysis但是Data_Analysis_Converteam

高温高压

于 2012-05-10T08:42:32.070 回答
1

要添加到 Siddhart 的答案 - 您可以像这样在 VBScript 中加载所需的插件：

objExcel.RegisterXLL("analys32.xll") 'For XLL addins
objExcel.Workbooks.Open(objExcel.LibraryPath & "\analysis\atpvbaen.xla") 'For standard XLA addins
objExcel.Workbooks.Open("C:\Program Files\MyAddins\MyAddin.xla") 'for custom XLA addins
于 2012-05-10T09:47:22.123 回答