7

我对 perl 中的代码块有疑问。给定以下代码：

    my @newArr = sort { $a <=> $b } @oldArr;

使用代码块作为参数。

我可以将其重写为：

    sub sortFunc {
        return $a <=> $b;
    }
    my @newArr = sort sortFunc @oldArr;

我试图弄清楚这种机制是如何工作的。目前我需要实现一种复杂的排序函数，它在代码块中看起来很乱，但是它取决于一些局部变量。例如：

   foreach my $val (@values){
       my @newArr = sort { $hash{$a}{$val}<=> $hash{$b}{$val} } @oldArr;
       ...
   }

但是让我们假设 sort 函数更复杂，所以它不会完全适合上面的代码。

如果我尝试使用函数（在 for 循环范围内本地定义），我会不断收到“在哈希元素中使用未初始化的值”。

我认为这是因为 sub 被解析一次，而不是为 for 循环的每次迭代重新创建。我试图了解如何实现一个每次迭代都会重新解释的代码块，或者如何传递参数

4

3 回答 3

9

由于某种原因，您没有显示有问题的代码，但我认为它类似于

for my $val (@values) {
   sub sort_func {
      return $hash{$a}{$val} <=> $hash{$b}{$val};
   }

   my @newArr = sort sort_func @oldArr;
}
我试图弄清楚这种机制是如何工作的。[...] 我认为这是因为 sub 被解析一次，而不是为 for 循环的每次迭代重新创建。

不完全的。以下仅解析和编译子一次，但它可以工作：

for my $val (@values) {
   my $cmp_func = sub {
      return $hash{$a}{$val} <=> $hash{$b}{$val};
   };

   my @newArr = sort $cmp_func @oldArr;
}

重要的是什么时候$val被捕获。被评估$val时被捕获。sub { ... }请记住，

sub foo { ... }

在这方面与以下相同，

BEGIN { *foo = sub { ... }; }

$val在我的代码中，它从 foreach 循环中捕获。在您的中，它在编译时捕获，因此它捕获$val在编译时存在的内容。这不是你想要的变量。

既然您知道如何使其工作，您就可以根据需要将复杂的代码移开（退出循环）。

sub make_cmp_func {
   my ($hash, $val) = @_;
   return sub {
      return $hash->{$a}{$val} <=> $hash{$b}{$val};
   };
}

for my $val (@values) {
   my $cmp_func = make_cmp_func(\%hash, $val);
   my @newArr = sort $cmp_func @oldArr;
}

或者，您可以将必要的值传递给比较函数，而不是捕获它们。

sub cmp_func {
   my ($hash, $val, $a, $b) = @_;
   return $hash->{$a}{$val} <=> $hash{$b}{$val};
}

for my $val (@values) {
   my @newArr = sort { cmp_func(\%hash, $val, $a, $b) } @oldArr;
}
于 2012-05-08T15:57:00.393 回答
8

您想使用除$a和之外还接受参数的函数$b。

sub my_sort_func {
    my ($val, $a, $b) = @_;
    return $hash{$a}{$val} <=> $hash{$b}{$val};
}

foreach my $val (@values) {
    my @newArr = sort { my_sort_func($val,$a,$b) } @oldArr;
    ...
}

Perl 使用代码块的机制sort有些特殊，在纯 Perl 中不容易复制。

于 2012-05-08T15:29:29.850 回答
5

扩展暴民的答案，这是“聪明但不一定聪明”的品种之一。如果你反对额外的参数，你可以使用柯里化来代替。

sub make_sorter {
    my ($hashref, $val) = @_;
    return sub {
          $hashref->{$a}{$val} <=> $hashref->{$b}{$val}
    };
}

for my $val (@values) {
    my $sorter = make_sorter(\%hash, $val);
    my @newArr = sort $sorter @oldArr;
}

无论如何，这并没有更有效、更易读或更有价值，但了解该技术在实际有用的地方可能会很有趣。

于 2012-05-08T15:38:35.893 回答