15

我想绘制一个球体，我知道如何在 OpenGL 中使用诸如 glBegin() 和 glEnd() 之类的调用来绘制。

但是ES中什么都没有。

建议/教程链接？

4

1 回答 1

47

由于您已使用 OpenGL ES 2.0 对此进行了标记，因此我建议您使用另一种方法来创建平滑球体，即将它们绘制为光线追踪的冒名顶替者。无需计算复制平滑球体所需的许多顶点，您可以利用球体从任何角度看起来几乎相同的事实。

为此，您采用如下流程：

球体冒名顶替者生成

您将代表两个三角形的四个顶点发送到顶点着色器，然后将它们置换以创建一个始终面向用户的正方形。在该正方形内，您使用片段着色器对每个像素进行光栅化，并提供通过该正方形窗口查看球体时球体在该点所具有的颜色。

这种方法的优点是球体与显示器支持的分辨率一样平滑，并且球体可以轻松地从小到大缩放，而无需重新计算几何。它确实将渲染的负担从顶点处理器转移到了片段处理器，但对于单个球体，这在我使用过的 OpenGL ES 2.0 设备上并不是什么大问题。

我在这个 iOS 应用程序中使用了这种技术，该页面上提供了该应用程序的源代码，并在此处进一步讨论它。我使用的顶点着色器的简化版本如下所示：

attribute vec4 position;
attribute vec4 inputImpostorSpaceCoordinate;

varying mediump vec2 impostorSpaceCoordinate;
varying mediump vec3 normalizedViewCoordinate;

uniform mat4 modelViewProjMatrix;
uniform mediump mat4 orthographicMatrix;
uniform mediump float sphereRadius;

void main()
{
    vec4 transformedPosition;
    transformedPosition = modelViewProjMatrix * position;
    impostorSpaceCoordinate = inputImpostorSpaceCoordinate.xy;

    transformedPosition.xy = transformedPosition.xy + inputImpostorSpaceCoordinate.xy * vec2(sphereRadius);
    transformedPosition = transformedPosition * orthographicMatrix;

    normalizedViewCoordinate = (transformedPosition.xyz + 1.0) / 2.0;
    gl_Position = transformedPosition;
}

简化的片段着色器是这样的：

precision mediump float;

uniform vec3 lightPosition;
uniform vec3 sphereColor;
uniform mediump float sphereRadius;

uniform sampler2D depthTexture;

varying mediump vec2 impostorSpaceCoordinate;
varying mediump vec3 normalizedViewCoordinate;

const mediump vec3 oneVector = vec3(1.0, 1.0, 1.0);

void main()
{
    float distanceFromCenter = length(impostorSpaceCoordinate);

    // Establish the visual bounds of the sphere
    if (distanceFromCenter > 1.0)
    {
        discard;
    }

    float normalizedDepth = sqrt(1.0 - distanceFromCenter * distanceFromCenter);

    // Current depth
    float depthOfFragment = sphereRadius * 0.5 * normalizedDepth;
    //        float currentDepthValue = normalizedViewCoordinate.z - depthOfFragment - 0.0025;
    float currentDepthValue = (normalizedViewCoordinate.z - depthOfFragment - 0.0025);

    // Calculate the lighting normal for the sphere
    vec3 normal = vec3(impostorSpaceCoordinate, normalizedDepth);

    vec3 finalSphereColor = sphereColor;

    // ambient
    float lightingIntensity = 0.3 + 0.7 * clamp(dot(lightPosition, normal), 0.0, 1.0);
    finalSphereColor *= lightingIntensity;

    // Per fragment specular lighting
    lightingIntensity  = clamp(dot(lightPosition, normal), 0.0, 1.0);
    lightingIntensity  = pow(lightingIntensity, 60.0);
    finalSphereColor += vec3(0.4, 0.4, 0.4) * lightingIntensity;

    gl_FragColor = vec4(finalSphereColor, 1.0);
}

这些着色器的当前优化版本有点难以遵循，而且我还使用了环境光遮蔽照明，这些都没有。也没有显示这个球体的纹理，这可以通过适当的映射函数在球体表面坐标和矩形纹理之间转换来完成。这就是我为球体表面提供预先计算的环境光遮蔽值的方式。

于 2012-05-08T20:41:54.543 回答