sql - 我如何检查同义词是否已经存在然后不要创建同义词

Question

我正在使用 Oracle SQL developer 2.1 创建同义词。

CREATE OR REPLACE SYNONYM "ETKS_PR_RW"."SQ_CLDOS_ATCHMNT_ID" 
    FOR "CLDOS_ONLINE_DBA"."SQ_CLDOS_ATCHMNT_ID";

我如何检查该同义词是否已经存在，如果存在则不要创建同义词。

Answer 1

当您使用replace关键字时，无需先检查同义词是否存在。您将覆盖以前名称存在的任何同义词。

谨慎使用的唯一原因replace是您可能有同名的不同同义词。如果您的数据库组织良好，则不应该发生这种情况。您应该始终知道所有对象是什么以及同义词指向的位置。

但是，如果您确实想要，有几个选项：

1. 删除replace. 如果同义词已经存在并且不会被覆盖，则该语句将引发错误。

2. 查询数据字典，因为您在多个模式中all_synonyms似乎是最好的选择。

   select *
     from all_synonyms
    where owner = 'ETKS_PR_RW'
      and synonym_name = 'SQ_CLDOS_ATCHMNT_ID';
   

如果您想将它们组合成一个块，那么您可以执行以下操作：

declare

   l_exists number;

begin
   -- check whether the synonym exists
   select 1
     into l_exists
     from all_synonyms
    where owner = 'ETKS_PR_RW'
      and synonym_name = 'SQ_CLDOS_ATCHMNT_ID';

-- an error gets raise if it doesn-t.
exception when no_data_found then
   -- DDL has to be done inside execute immediate in a block.
   execute immediate 'CREATE OR REPLACE SYNONYM ETKS_PR_RW.SQ_CLDOS_ATCHMNT_ID 
                   FOR CLDOS_ONLINE_DBA.SQ_CLDOS_ATCHMNT_ID';

end;
/

在一个稍微分开的不请不要引用你的对象名称。Oracle 可以有 cased 对象，但它非常非常不值得麻烦。所有对象都将自动大写，因此您不需要".

Answer 2

我认为如果您删除了 OR REPLACE 关键字，它会提示您它存在

或者您可以使用这些表创建 pl/sql 代码

desc dba_synonyms
desc user_synonyms

使其更加灵活和定制

假设 Oracle PL/SQL

DECLARE
    src_schema    VARCHAR2(256) := 'EMPIK_DYNAMO_01';
    target_schema VARCHAR2(256) := 'EMPIK_PORTAL_BETA_1';
    CURSOR src_objects IS
      SELECT table_name AS object_name
      FROM   all_all_tables
      WHERE  owner = src_schema
      UNION
      SELECT sequence_name AS object_name
      FROM   all_sequences
      WHERE  sequence_owner = src_schema;
BEGIN
    FOR next_row IN src_objects LOOP
        BEGIN
            EXECUTE IMMEDIATE 'CREATE or REPLACE SYNONYM '|| target_schema|| '.'
            ||
            next_row.object_name|| ' for '|| src_schema|| '.'||
            next_row.object_name;
        EXCEPTION
            WHEN OTHERS THEN
              dbms_output.Put_line('ERROR WHILE CREATING SYNONYM FOR: '
                                   || next_row.object_name);

              dbms_output.Put_line(SQLERRM);
        END;
    END LOOP;
END;

/ 

在这里为您的问题定制

BEGIN
    EXECUTE IMMEDIATE 'CREATE or REPLACE SYNONYM ETKS_PR_RW.SQ_CLDOS_ATCHMNT_ID FOR CLDOS_ONLINE_DBA.SQ_CLDOS_ATCHMNT_ID';  
EXCEPTION
    WHEN OTHERS THEN
      dbms_output.Put_line ('ERROR WHILE CREATING SYNONYM FOR: SQ_CLDOS_ATCHMNT_ID');
      dbms_output.Put_line (SQLERRM);
END;