haskell - emacs haskell模式下的默认lambda符号？

Question

有谁知道我如何在emacs中使用haskell打印λ而不是\。我知道可以使用haskell-font-lock-symbols，但我发现其余的很难阅读——箭头太小了！

有没有一种简单的方法可以覆盖其余的键？

Answer 1

您还可以使用类似的方法解决问题

(eval-after-load 'haskell-font-lock
 '(setq haskell-font-lock-symbols-alist
        (delq nil
              (mapcar (lambda (rewrite)
                        (if (member (car rewrite) '("->" "<-"))
                            nil rewrite))
                      haskell-font-lock-symbols-alist))))

它应该保留所有映射，除了将“->”更改为“→”和“<-”更改为“←”的映射。

Answer 2

你可以这样做：

(defun pretty-lambdas-haskell ()
  (font-lock-add-keywords
   nil `((,(concat "\\(" (regexp-quote "\\") "\\)")
          (0 (progn (compose-region (match-beginning 1) (match-end 1)
                                    ,(make-char 'greek-iso8859-7 107))
                    nil))))))

(add-hook 'haskell-mode-hook 'pretty-lambdas-haskell)

这会将 lambda 添加为关键字，这意味着它不会出现在例如字符串的转义序列中（TODO：更改事物后不会出现这种情况）。,(make-char 'greek-iso8859-7 107)当然 等同于，但在这种?λ情况下，您必须确保您的 Emacs 初始化文件被编码为 un​​icode。

您还可以启用完整的符号字体锁定并使用更好的（阅读：使用更宽的箭头）字体，例如Pragmata Pro、Inconsolata或Ubuntu Monospace。我使用以下代码来选择一个好的字体：

(defun font-existsp (font)
  "Check to see if the named FONT is available."
  (if (null (x-list-fonts font))
      nil t))

(require 'cl)
(defun font-avail (fonts)
  "Finds the available fonts."
  (remove-if-not 'font-existsp fonts))

(defvar font-preferences
      '("PragmataPro"
        "Inconsolata"
        "DejaVu Sans Mono"
        "Bitstream Vera Sans Mono"
        "Anonymous Pro"
        "Menlo"
        "Consolas"))

(unless (eq window-system nil)
  (let ((fonts (font-avail font-preferences)))
    (unless (null fonts)
      (set-face-attribute
       'default nil :font
       (car fonts)))))