4

我需要一个小技巧来让我的解析器完全工作。我使用 antlr 来解析布尔查询。

查询由元素组成，通过 ands、ors 和 nots 链接在一起。

所以我可以有类似的东西：

"(P or not Q or R) or (( not A  and B) or C)"

问题是，一个元素可以很长，并且通常采用以下形式：

a an_operator b

例如 ：

"New-York matches NY"

技巧，其中一个 an_operator 是“不像”

所以我想修改我的词法分析器，以便 not 检查它后面是否有类似，以避免解析包含“不喜欢”运算符的元素。

我目前的语法在这里：

// save it in a file called Logic.g
grammar Logic;

options {
  output=AST;
}

// parser/production rules start with a lower case letter
parse
  :  expression EOF!    // omit the EOF token
  ;

expression
  :  orexp
  ;

orexp
  :  andexp ('or'^ andexp)*    // make `or` the root
  ;

andexp
  :  notexp ('and'^ notexp)*      // make `and` the root
  ;

notexp
  :  'not'^ atom    // make `not` the root
  |  atom
  ;

atom
  :  ID
  |  '('! expression ')'!    // omit both `(` andexp `)`
  ;

// lexer/terminal rules start with an upper case letter
ID    : ('a'..'z' | 'A'..'Z')+;
Space : (' ' | '\t' | '\r' | '\n')+ {$channel=HIDDEN;};

任何帮助，将不胜感激。谢谢 ！

4

1 回答 1

4

这是一个可能的解决方案：

grammar Logic;

options {
  output=AST;
}

tokens {
  NOT_LIKE;
}

parse
  :  expression EOF!
  ;

expression
  :  orexp
  ;

orexp
  :  andexp (Or^ andexp)*
  ;

andexp
  :  fuzzyexp (And^ fuzzyexp)*
  ;

fuzzyexp
  :  (notexp -> notexp) ( Matches e=notexp  -> ^(Matches $fuzzyexp $e)
                        | Not Like e=notexp -> ^(NOT_LIKE $fuzzyexp $e)
                        | Like e=notexp     -> ^(Like $fuzzyexp $e)
                        )?
  ;

notexp
  :  Not^ atom
  |  atom
  ;

atom
  :  ID
  |  '('! expression ')'!
  ;

And     : 'and';
Or      : 'or';
Not     : 'not';
Like    : 'like';
Matches : 'matches';
ID      : ('a'..'z' | 'A'..'Z')+;
Space   : (' ' | '\t' | '\r' | '\n')+ {$channel=HIDDEN;};

这会将输入解析"A not like B or C like D and (E or not F) and G matches H"为以下 AST：

在此处输入图像描述

于 2012-05-04T15:43:16.300 回答