4

似乎 EXSLT 标记化功能不适用于 PHP XSLTProcessor (XSLT 1.0)。

我试图在纯 XSL 中实现它，但我无法让它工作：

<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:func="http://exslt.org/functions"
    xmlns:exsl="http://exslt.org/common"
    xmlns:my="http://mydomain.com/">

    <func:function name="my:tokenize">
        <xsl:param name="string"/>
        <xsl:param name="separator" select="'|'"/>
        <xsl:variable name="item" select="substring-before(concat($string,$separator),$separator)"/>
        <xsl:variable name="remainder" select="substring-after($string,$separator)"/>
        <xsl:variable name="tokens">
            <token><xsl:value-of select="$item"/></token>
            <xsl:if test="$remainder!=''">
                <xsl:copy-of select="my:tokenize($remainder,$separator)"/>
            </xsl:if>
        </xsl:variable>
        <func:result select="exsl:node-set($tokens)"/>
    </func:function>

    <xsl:template match="/">
        <xsl:copy-of select="my:tokenize('a|b|c')"/>
    </xsl:template>

</xsl:stylesheet>

预期结果 ：

    <token>a</token><token>b</token><token>c</token>

实际结果 ：

    abc

我知道这个问题已经发布了很多次，但我找不到一个简单的解决方案。

感谢您的帮助。

4

3 回答 3

7

引用http://www.exslt.org/str/functions/tokenize/index.html

以下 XSLT 处理器支持 str:tokenize：

  • 4XSLT，来自 4Suite。（版本 0.12.0a3）
  • 来自 Daniel Veillard 等人的 libxslt。（版本 1.0.19）

由于 PHP 使用 libxslt，这意味着tokenize可用，但您必须使用正确的扩展名称空间（您不这样做）：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:str="http://exslt.org/strings"
    extension-element-prefixes="str"
    …

然后你可以使用 tokenize 作为一个函数，例如构建一个带有数字 1-12 的选择框：

<select name="months">
    <xsl:for-each select="str:tokenize('1,2,3,4,5,6,7,8,9,10,11,12', ',')">
        <xsl:element name="option">
            <xsl:attribute name="value">
                <xsl:value-of select="."/>
            </xsl:attribute>
            <xsl:value-of select="."/>
        </xsl:element>
    </xsl:for-each>
</select>
于 2012-05-04T10:56:39.703 回答
2

我可能有点过时，因为我不使用函数，但是我有以下tokenize模板，它可以满足您的需求，无需任何特殊扩展：

<xsl:template name="tokenize">
  <xsl:param name="string"/>
  <xsl:param name="separator" select="'|'"/>

  <xsl:choose>
    <xsl:when test="contains($string,$separator)">
      <token>
        <xsl:value-of select="substring-before($string,$separator)"/>
      </token>
      <xsl:call-template name="tokenize">
        <xsl:with-param name="string" select="substring-after($string,$separator)"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <token><xsl:value-of select="$string"/></token>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

它按如下方式调用，应该为您提供所需的输出：

<xsl:call-template name="tokenize">
  <xsl:with-param name="string" select="'a|b|c'"/>
</xsl:call-template>
于 2012-05-04T11:48:59.307 回答
0

您不必编写自己的实现 - 只需使用现有的FXSL str-split-to-words模板，它提供了更强大的功能。

这是一个简短的使用演示str-split-to-words：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common">

   <xsl:import href="strSplit-to-Words.xsl"/>
   <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:variable name="vwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters" 
                          select="', &#9;&#10;&#13;'"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
    </xsl:template>

    <xsl:template match="word">
      <xsl:value-of select="concat(position(), ' ', ., '&#10;')"/>
    </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>out, of
 luck</t>

产生了想要的结果 - 所有单词及其位置的序列。

请注意，参数中提供的任何最大长度的相邻分隔符字符序列都pDelimiters用作分隔符：

1 out
2 of
3 luck
于 2012-05-04T12:18:57.127 回答