0

我有一个旧的 Fortran 程序，用于从文本文件中读取记录。记录格式如下：

record_type field1 field2 ... fieldN ;

这些记录可能分布在几行，字符 ; 表示记录已经结束。旧代码是：

2 read(data,"(a130)",end=3)line
  shift=adrec(nbrec)-1
  read(line,*,end=1)typrec(nbrec),(field(shift+i),i=1,65)
1 do
    do j=shift+1,shift+i-1
      k=index(field(j),';')
      if(k .ne. 0)then
        if(k .eq. 1)then
          adrec(nbrec+1)=j
        else
          field(j)(k:)=''
          adrec(nbrec+1)=j+1
        endif
          go to 2
      endif
    endo
    read(data,"(a130)")line
    read(line,*,end=1)(field(shift+i),i=1,65)
  enddo
3 continue

此代码可与英特尔编译器 (ifort) 一起使用。使用 gfortran 它失败了！第一个问题是第三行的隐式读取，使用 ifort，使 i 等于实际读取的字段数，而在 gfortran 中它总是给出 65。第二个问题是在相同的隐式读取中，使用 ifort ， 性格 ; 被读取为普通字段，但 gfortran 被跳过。

谁能帮我解决这两个问题？也欢迎任何其他将代码全部替换的想法。

4

1 回答 1

1

这行得通吗？除了do while（和exit控制结构......）之外，这是符合 f77 的（我认为）。如果需要，do while 可以相对容易地被 goto/continue 替换。我不知道你最终希望字符串是什么类型，所以我返回字符串（并假设一个字段不能超过 24 个字符）......我还假设一个“行”不能超过 1024人物。很抱歉缺少评论，但我认为函数名称的描述性已经足够了。一般来说，我认为在编程时使用函数/子例程是个好主意，因为这会使代码更具可读性......

  program main
  character*1024 line
  integer stat,stat2,i,nf
  character*24 fld
  character*16 fmt

  open(unit=21,file='test.dat',status='old')
  stat=0
  do while(stat.eq.0)
     call readline(21,line,stat)
     stat2=0
     i=1
     do while(.true.)
        call getfield(line,fld,stat2)
        if(stat2.ne.0) exit
        i=i+1
        write(*,*) i,stat2,fld
     enddo
     write(*,*) " "
  enddo


  end

  subroutine getfield(line,field,stat)
  integer l,i,stat
  character*(*) line,field
  !Get first field and shift the line
  l=1
  if(line.eq.' ')then
     stat=1
  else
     stat=0
  endif
  do while (line(l:l).eq.' ')
     l=l+1
  enddo
  i=l
  do while (line(i:i).ne.' ')
     i=i+1
  enddo

  if((line(l:l).eq.'"').or.(line(l:l).eq."'"))then
     do while(line(i:i).ne.line(l:l))
        i=i+1
     enddo
  endif

  field=line(l:i)
  line=line(i+1:)
  return
  end

  subroutine readline(unit,line,stat)
  integer unit
  character*(*) line
  integer stat,i
  !read one "line"  Lines are sequences seperated by ';' (can have newlines in there) 

  stat=0
  i=1
  do while (.true.)
     read(unit,'(A)',end=100) line(i:)
     i=index(line,';')
     if(i.eq.0)then
        i=len_trim(line)+2
     else
        line(i:)=' ' !remove the trailing semicolon.
        exit
     endif
  enddo

  return
 100  continue
  stat=1
  return
  end
于 2012-05-02T05:01:11.357 回答