perl - 通过多个键对哈希数组进行排序 Perl

Question

我有一个包含哈希的数组引用（即@AOH）

$arr_ref = [ { 'brand' => 'A',
               'supplier' => 'X',
               'PO' => '2'
              },
              { 'brand' => 'B',
                'supplier' => 'Y',
                'PO' => '1'       
              },
              { 'brand' => 'B',
                'supplier' => 'X',
                'PO' => '2'           
              },
              { 'brand' => 'A',
                'supplier' => 'X',
                'PO' => '1'
              },
              { 'brand' => 'B',
                'supplier' => 'X',
                'PO' => '1'           
              }
];

我想根据所有三个键（即品牌、供应商和采购订单）对其进行排序。排序顺序应该是先品牌，然后是供应商，最后是PO。

排序后的数组引用应该是：

$arr_ref = [ { 'brand' => 'A',
                'supplier' => 'X',
                'PO' => '1'
              },
              { 'brand' => 'A',
               'supplier' => 'X',
               'PO' => '2'
              },
              { 'brand' => 'B',
                'supplier' => 'X',
                'PO' => '1'           
              },
              { 'brand' => 'B',
                'supplier' => 'X',
                'PO' => '2'           
              },              
              { 'brand' => 'B',
                'supplier' => 'Y',
                'PO' => '1'       
              },
];

Answer 1

由于<=>andcmp返回 0 表示相等，这是错误的，并且因为 Perl 的逻辑布尔运算符返回决定值而不是仅仅 0 或 1，所以按多个键排序就像将多个比较串在一起一样简单oror ||：

@$arr_ref = sort { $a->{brand}    cmp $b->{brand}    or 
                   $a->{supplier} cmp $b->{supplier} or 
                   $a->{PO}       <=> $b->{PO} 
                 } @$arr_ref;

我假设 PO 是一个数字字段，所以你使用<=>它而不是cmp.

Answer 2

以下应该对数组引用进行排序并将数组放回$arr_ref：

$arr_ref = [sort by_brand_supplier_PO @$arr_ref];

sub by_brand_supplier_PO {
    $a->{brand} cmp $b->{brand} ||
    $a->{supplier} cmp $b->{supplier} ||
    $a->{PO} <=> $b->{PO}
}

Answer 3

您可以使用Sort::Key::Multi，与 Sort::Key 一起分发。

在这种情况下，我们使用ssikeysort，它需要一个返回字符串、字符串和整数的块，并按该元组对值进行排序。（sinssi代表字符串， in 代表i整数。）

use Sort::Key::Multi qw(ssikeysort);

@$arr_ref = ssikeysort { $_->{brand}, $_->{supplier}, $_->{PO} } @$arr_ref;

---

您还可以使用 in-place 变体，它使用更少的内存：

use Sort::Key::Multi qw(ssikeysort_inplace);

ssikeysort_inplace { $_->{brand}, $_->{supplier}, $_->{PO} } @$arr_ref;