perl - 动态填充哈希：一个文件中的键和另一个文件中的值

Question

所以我有一个带有以下行的文本文件：

123456789

但后来我有第二个文件：

987654321

那么我怎样才能使第一个文件的内容keys成为哈希，而第二个文件的值values呢？（每个字符都是一个键/值）

我应该将每个文件存储到不同的数组中，然后以某种方式合并它们吗？我该怎么做？还要别的吗？

老实说，我会给你我尝试过的代码，但我一点也不知道从哪里开始。

Answer 1

您可以使用散列片。

如果每一行都是一个键/值：（s///r需要5.14，但可以很容易地为早期版本重写）

my %h;
@h{ map s/\s+\z//r, <$fh1> } = map s/\s+\z//r, <$fh2>;

如果每个字符都是键/值：

my %h;
{
   local $/ = \1;
   @h{ grep !/\n/, <$fh1> } = grep !/\n/, <$fh2>;
}

Answer 2

只需打开两个文件并同时逐行读取它们：

use strict; use warnings;
use autodie;

my %hash;
open my $keyFile, '<', 'keyfileName';
open my $valueFile, '<', 'valuefileName';

while(my $key = <$keyFile>) {
   my $value = <$valueFile>;
   chomp for $key, $value;       
   $hash{$key} = $value;
}

当然，这只是一个关于它如何工作的快速草图。

Answer 3

OP提到每个字符都是一个键或值，我认为你的意思是输出应该是一个像( 1 => 9, 2 => 8, ... ). OP还问：

我应该将每个文件存储到不同的数组中，然后以某种方式合并它们吗？我该怎么做？

这正是这个答案的工作原理。这get_chars是一个读取每个文件、拆分每个字符并返回该数组的函数。然后使用zipfromList::MoreUtils创建哈希。

#!/usr/bin/env perl

use strict;
use warnings;

use List::MoreUtils 'zip';

my ($file1, $file2) = @ARGV;

my @file1chars = get_chars($file1);
my @file2chars = get_chars($file2);

my %hash = zip @file1chars, @file2chars;

use Data::Dumper;
print Dumper \%hash;

sub get_chars {
  my $filename = shift;
  open my $fh, '<', $filename 
    or die "Could not open $filename: $!";

  my @chars;
  while (<$fh>) {
    chomp;
    push @chars, split //;
  }
  return @chars;
}

Answer 4

迭代器疯狂：

#!/usr/bin/env perl

use autodie;
use strict; use warnings;

my $keyfile_contents = join("\n", 'A' .. 'J');
my $valuefile_contents = join("\n", map ord, 'A' .. 'E');

# Use get_iterator($keyfile, $valuefile) to read from physical files

my $each = get_iterator(\ ($keyfile_contents, $valuefile_contents) );

my %hash;
while (my ($k, $v) = $each->()) {
    $hash{ $k } = $v;
}

use YAML;
print Dump \%hash;

sub get_iterator {
    my ($keyfile, $valuefile) = @_;

    open my $keyf, '<', $keyfile;
    open my $valf, '<', $valuefile;

    return sub {
        my $key = <$keyf>;
        return unless defined $key;
        my $value = <$valf>;
        chomp for grep defined, $key, $value;
        return $key => $value;
    };
}

输出：

C:\temp> 年
---
答：65
乙：66
C: 67
D: 68
E: 69
楼：~
格：~
哈：~
我：~
J：~

Answer 5

我会写

my %hash = ('123456789' => '987654321');