0

我有一个哈希值是数组。我需要找到这些数组的共同元素，即。存在于所有数组中的元素。所以我将散列的值提取到一个多维数组中，其每一行对应于散列中的一个数组。然后我将该矩阵的第一行放入另一个数组 (@arr1) 并遍历它以查找 arr1 中是否有任何元素也在矩阵的其余行中。如果找到这样的元素，则将其推送到包含所有元素的最终列表的另一个数组中。代码如下（希望够清楚）：

sub construct_arr(my %records) {
    my $len = keys %records;
    my @matrix;
    my $i = 0;

    # Extract the values of the hash into a matrix
    foreach my $key (keys %records) {
        $matrix[$i] = $records{$key};
        $i++;   
    }

    my @arr1 = $matrix[0];
    my @final;

    # Iterate through each element of arr1
    for my $j (0..$#{$arr1[0]}) {
        my $count = 1;

        # Iterate through each row of the matrix, starting from the second
        for ( my $i = 1; $i < $len ; $i++ ) {
            my $flag = 0;

            # Iterate through each element of the row
            for my $k (0..$#{$matrix[$i]}) {
                if ($arr1[0][$j] eq $matrix[$i][$k]) {
                    $flag = 1;
                    $count++;
                }
            }

            # On finding the first instance of the element in a row, go to the next row
            if (!$flag == 1) {
                last;
            }       
        }

        # If element is in all the rows, push it on to the final array
        if ($count == $len) {
            push(@final, $arr1[0][$j]);
        }
    }
    return @final;
}

我知道上述方法有效，但我想知道是否有任何其他（perlish）方法可以做到这一点。我开始学习 perl，我很想知道与其他语言相比，可以让我在 perl 中的工作更轻松的事情。如果我的代码是可以做到的最好的，也请告诉我。任何指导将不胜感激。谢谢！

4

3 回答 3

6

查看Chris Charley 的计算数组交集的链接。

哈希是解决此类问题的明确方法。map和一个解决方案一起grep可以减少到几行。

该程序使用sundar 的数据来解决任何更好的问题，并且似乎可以满足您的需要。

use strict;
use warnings;

my %records = (
  a => [ qw/ A B C / ],
  b => [ qw/ C D E A / ],
  c => [ qw/ A C E / ],
);

print "$_\n" for construct_arr(\%records);

sub construct_arr {
  my $records = shift;
  my %seen;
  $seen{$_}++ for map @$_, values %$records;
  grep $seen{$_} == keys %$records, keys %seen;
}

输出

A
C

编辑

我认为查看您自己的解决方案的更 Perlish、整洁的版本可能会有所帮助。

use strict;
use warnings;

my %records = (
  a => [ qw/ A B C / ],
  b => [ qw/ C D E A / ],
  c => [ qw/ A C E / ],
);

print "$_\n" for construct_arr(\%records);

sub construct_arr {

  my $records = shift;
  my @matrix = values %$records;
  my @final;

  # iterate through each element the first row
  for my $i ( 0 .. $#{$matrix[0]} ) {

    my $count = 1;

    # look for this value in all the rest of the rows, dropping
    # out to the next row as soon as a match is found
    ROW:
    for my $j ( 1 .. $#matrix ) {
      for my $k (0 .. $#{$matrix[$j]}) {
        next unless $matrix[0][$i] eq $matrix[$j][$k];
        $count++;
        next ROW;
      }
    }

    # If element is in all the rows, push it on to the final array
    push @final, $matrix[0][$i] if $count == @matrix;
  }

  return @final;
}

输出与我自己的程序相同，但功能略有不同，因为我假设每行中的值都是唯一的。如果 sama 值多次出现，我的解决方案将中断（这同样适用于sundar's）。请让我知道这是否可以接受。

于 2012-04-28T17:51:53.120 回答
3

尽管张贴者解释说单个数组中没有重复项，但我的尝试也处理了这种情况（请注意稍作修改的测试数据 - 不应打印“5”）：

#!/usr/bin/env perl
use warnings;
use strict;

my %records = (
    a => [1, 2, 3],
    b => [3, 4, 5, 1],
    c => [1, 3, 5, 5]
);

my %seen;
while (my ($key, $vals) = each %records) {
    $seen{$_}{$key} = 1 for @$vals;
}

print "$_\n" for grep { keys %{$seen{$_}} == keys %records } keys %seen;
于 2012-04-29T01:17:32.557 回答
1

您可以使用轻松找到散列的大小scalar(keys %hash);

这是一个示例代码，可以满足您的需要：

#!/usr/bin/perl

use strict;
use warnings;

my %records = ( a => [1, 2, 3],
                b => [3, 4, 5, 1],
                c => [1, 3, 5]
              );

my %count;
foreach my $arr_ref (values %records) {
    foreach my $elem (@$arr_ref) {
        $count{$elem}++;
    }
}

my @intersection;
my $num_arrays = scalar(keys %records);
foreach my $elem (keys %count) {
    #If all the arrays contained this element, 
    #allowing for multiple entries per array
    if ($count{$elem} >= $num_arrays) {
        push @intersection, $elem;
    }
}

如果您需要对此代码进行任何说明，请随时发表评论。构造 @intersection 数组的第二个 foreach 只是为了清楚起见才以这种方式编写 - 如果您正在学习 Perl，我建议您使用该map构造来学习和重写它，因为这可以说是更惯用的 Perl。

于 2012-04-28T16:42:56.407 回答