0

我正在创建存储过程，我需要在其中动态构建一个临时表。我尝试了以下代码，但它没有创建表。当我在查询窗口中执行生成的查询时，它在那里工作正常。 

--declare query variable
DECLARE @Query nvarchar(MAX)
SET @Query = 'CREATE TABLE #final (DATE int,'   


--DECLARE @COLUMNNAME VARIABLE
DECLARE @ColName nvarchar(10)

OPEN @taCur

FETCH NEXT FROM @taCur INTO @ColName
WHILE (@@FETCH_STATUS = 0)
BEGIN
    SET @Query = @Query + 'T_' + @ColName +' int,'   
    FETCH NEXT FROM @taCur INTO @ColName
END

SET @Query = @Query + 'TOTAL int,CUMM_TOTAL int)'
print @Query
EXEC sp_executesql @Query
--SET @Query = 'INSERT INTO #final (DATE) VALUES (1)'
SET @Query = 'SELECT * FROM #final'
print @Query
EXEC(@Query)

最终生成的创建表查询如下

CREATE TABLE #final (DATE int,T_211E int,T_211G int,T_211H int,T_211J int,T_211L int,T_221F int,TOTAL int,CUMM_TOTAL int)
4

2 回答 2

3

您的问题是您的临时表仅存在于它创建的范围内......在您的第一个sp_executesql. 当您调用您的select语句时，您的临时表不再在范围内。

要解决此问题，您必须构建一个字符串，其中包含您需要对临时表执行的所有操作：您的create、、insert以及select在单个sp_executesql调用中的所有内容。

但是，您应该知道，如果您无法完全控制用于构建命令的所有值，那么您当前的方法很可能容易受到 SQL 注入的影响。

于 2012-04-28T04:02:20.357 回答
3

CREATE和SELECT语句中使用的对象#final不在同一范围内。

这是构造查询的一种方法。

  • 尝试用分号终止 SQL 语句。即使它不是强制性的，它也会帮助您区分语句以提高可读性。请注意，我在CREATE、INSERT和SELECT语句的末尾添加了分号。

  • 您会注意到CREATE、INSERT和SELECT在同一个事务中执行。因此，您不会丢失临时表的范围。

脚本：

    CREATE TABLE dbo.ColumnSchema
    (
        ColName NVARCHAR(10)
    );

    INSERT INTO dbo.ColumnSchema (ColName) VALUES
        ('211E'),
        ('211G'),
        ('211H'),
        ('211J'),
        ('211L'),
        ('211F');


DECLARE @Query      NVARCHAR(MAX);
DECLARE @ColName    NVARCHAR(10);

SET @Query = 'CREATE TABLE #final (DATE int,';

DECLARE taCursor CURSOR FOR 
    SELECT  ColName
    FROM    dbo.ColumnSchema;

OPEN taCursor

FETCH NEXT FROM taCursor 
    INTO @ColName

    WHILE (@@FETCH_STATUS = 0)
    BEGIN

        SET @Query = @Query + 'T_' + @ColName + ' int, '   

        FETCH NEXT FROM taCursor 
            INTO @ColName
    END

CLOSE       taCursor;
DEALLOCATE  taCursor;

SET @Query = @Query + 'TOTAL int,CUMM_TOTAL int); '
SET @Query = @Query + 'INSERT INTO #final (DATE) VALUES (1); '
SET @Query = @Query + 'SELECT * FROM #final; '

EXEC (@Query);

输出：

DATE T_211E T_211G T_211H T_211J T_211L T_211F TOTAL CUMM_TOTAL
---- ------ ------ ------ ------ ------ ------ ----- ----------
1    NULL   NULL   NULL   NULL   NULL   NULL   NULL  NULL
于 2012-04-28T04:05:22.237 回答