delphi - 如何在具有透明度和不透明度的画布上绘画？

Question

概述

从 GR32 库中，我使用 TImgView32 来渲染一个网格，这将是我的透明背景，如下所示：

放置在 TImgView32 内，我有一个常规的 TImage，我将在其中绘制到画布上，如下所示：

任务

我想要实现的是能够设置画笔的不透明度，从而为我的程序中的图像编辑提供更多可能性。设置画笔的不透明度允许不同级别的颜色深度等，而不是绘制一种平面颜色。

我早些时候在四处搜索时发现了这个问题：Draw opacity ellipse in Delphi 2010 - Andreas Rejbrand 在他对该问题的回答中提供了一些示例。

我看过 Andreas 做了什么，并想出了我自己的简化尝试，但我遇到了一个问题。看看下面这两张图片，第一张是透明背景，第二张是黑色背景，更清楚地显示问题：

如您所见，画笔（圆圈）周围是一个非常烦人的正方形，我无法摆脱。所有应该可见的是画笔。这是我用来产生这些结果的代码：

procedure DrawOpacityBrush(ACanvasBitmap: TBitmap; X, Y: Integer;
  AColor: TColor; ASize: Integer; Opacity: Integer);
var
  Bmp: TBitmap;
begin
  Bmp := TBitmap.Create;
  try
    Bmp.SetSize(ASize, ASize);
    Bmp.Transparent := False;

    with Bmp.Canvas do
    begin
      Pen.Color := AColor;
      Pen.Style := psSolid;
      Pen.Width := ASize;
      MoveTo(ASize div 2, ASize div 2);
      LineTo(ASize div 2, ASize div 2);
    end;

    ACanvasBitmap.Canvas.Draw(X, Y, Bmp, Opacity);
  finally
    Bmp.Free;
  end;
end;

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  DrawOpacityBrush(Image1.Picture.Bitmap, X, Y, clRed, 50, 85);
end;

在常规位图上产生：

我的想法（基于 Andreas 创建具有不透明度的椭圆的方法）是在画布上渲染一个典型的画笔，将其分配给屏幕外位图，然后将其重新绘制到具有不透明度的主位图上。哪个有效，除了边缘周围的那个烦人的正方形。

如屏幕截图所示，如何渲染具有不透明度的画笔，但在画笔圆圈周围没有那个正方形？

如果我设置Bmp.Transparent := True仍然有一个白框，但不再不透明。只是一个实心的白色正方形和实心填充的红色圆圈。

Answer 1

的不透明度功能TCanvas.Draw()不支持您尝试执行的操作，至少不支持您尝试使用它的方式。为了达到你想要的效果，你需要创建一个 32 位TBitmap，这样你就有一个每像素的 alpha 通道，然后为每个像素填充 alpha，将你不想要的像素的 alpha 设置为 0，并将alpha 到您想要的像素所需的不透明度。然后，在调用 时TCanvas.Draw()，将其不透明度设置为 255 以告诉它仅使用每像素不透明度。

procedure DrawOpacityBrush(ACanvas: TCanvas; X, Y: Integer; AColor: TColor; ASize: Integer; Opacity: Byte);
var
  Bmp: TBitmap;
  I, J: Integer;
  Pixels: PRGBQuad;
  ColorRgb: Integer;
  ColorR, ColorG, ColorB: Byte;
begin
  Bmp := TBitmap.Create;
  try
    Bmp.PixelFormat := pf32Bit; // needed for an alpha channel
    Bmp.SetSize(ASize, ASize);

    with Bmp.Canvas do
    begin
      Brush.Color := clFuchsia; // background color to mask out
      ColorRgb := ColorToRGB(Brush.Color);
      FillRect(Rect(0, 0, ASize, ASize));
      Pen.Color := AColor;
      Pen.Style := psSolid;
      Pen.Width := ASize;
      MoveTo(ASize div 2, ASize div 2);
      LineTo(ASize div 2, ASize div 2);
    end;

    ColorR := GetRValue(ColorRgb);
    ColorG := GetGValue(ColorRgb);
    ColorB := GetBValue(ColorRgb);

    for I := 0 to Bmp.Height-1 do
    begin
      Pixels := PRGBQuad(Bmp.ScanLine[I]);
      for J := 0 to Bmp.Width-1 do
      begin
        with Pixels^ do
        begin
          if (rgbRed = ColorR) and (rgbGreen = ColorG) and (rgbBlue = ColorB) then
            rgbReserved := 0
          else
            rgbReserved := Opacity; 
          // must pre-multiply the pixel with its alpha channel before drawing
          rgbRed := (rgbRed * rgbReserved) div $FF;
          rgbGreen := (rgbGreen * rgbReserved) div $FF;
          rgbBlue := (rgbBlue * rgbReserved) div $FF;
        end;
        Inc(Pixels);
      end;
    end;

    ACanvas.Draw(X, Y, Bmp, 255);
  finally
    Bmp.Free;
  end;
end;

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;  
  Shift: TShiftState; X, Y: Integer);  
begin  
  DrawOpacityBrush(Image1.Picture.Bitmap.Canvas, X, Y, clRed, 50, 85);  
end;